How to replace dots with commas in multiple csv files? - powershell

Question

I have semicolon delimited CSV file. Some numerical values are stored with decimal point, for other data manipulation I need to use numbers with decimal comma. This should run for each file in the same folder on any Win machine. Any ideas?
I have tried PowerShell successfully on single file using this script
(Get-Content VER_ZdnSort201608-20160908210028original.csv) | ForEach-Object { $_ -replace "\.", "," } | VER_ZdnSort201608-20160908210028new.csv
But I can't seem to get it work with multiple files, also without replacing content without creating new files.
The data looks like this:
520100;2016-08-31;3197.90;N0401
520200;2016-08-31;6406.66;N0401
520430;2016-08-31;536.40;N0401
520800;2016-08-31;1547.70;N0401
...
Output should be like this:
520100;2016-08-31;3197,90;N0401
520200;2016-08-31;6406,66;N0401
520430;2016-08-31;536,40;N0401
520800;2016-08-31;1547,70;N0401
...

Answer 1

The following will search in a given folder for .csv files. It will then replace any . with , in all .csv files found, overwriting the new text to the same file.
Get-ChildItem -Path C:\Folder -Filter '*.csv' | ForEach-Object {
(Get-Content $_.FullName).Replace('.',',') | Out-File $_.FullName
}

Answer 2

The following script constitutes a pure batch-file solution:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
for %%F in (%*) do (
for /F delims^=^ eol^= %%L in ('
type "%%~F" ^& ^> "%%~F" rem/
') do (
set "LINE=%%L"
setlocal EnableDelayedExpansion
>> "%%~F" echo(!LINE:.=,!
endlocal
)
)
endlocal
exit /B
Provide the paths to your CSV files as command line arguments. Supposing the script is named convert-decimal-point.bat and your CSV files are located in D:\Data, use this command line:
convert-decimal-point.bat "D:\Data\*.csv"
Here is a comprehensive solution that does not blindly replace every . by , but checks each field whether it truly contains a fractional number (an optional sign +/-, followed by any number of decimal digits, followed by ., followed by any number of decimal digits; for example 1.2, -.73, +12.584) or an exponential number (a fractional number, followed by E/e, followed by a sign +/-, followed by one or more decimal digits; for example, 1.2E-02, -.73e+5). This is the batch-file code:
#echo off
setlocal EnableExtensions DisableDelayedExpansion
rem // Define constants here:
set "_SEARCH=." & rem // (decimal point to search for)
set "_REPLAC=," & rem // (decimal point for replacing)
set "_SEPCHR=;" & rem // (field separator character)
rem // Predefine global variables here:
set "$HEADER=" & rem // (set to something to ignore first line)
for %%F in (%*) do (
for /F delims^=^ eol^= %%L in ('
type "%%~F" ^& ^> "%%~F" rem/
') do (
set "COLL=%_SEPCHR%" & set "LINE=%%L"
setlocal EnableDelayedExpansion
set "LINE=!LINE:"=""!^"
if "!LINE:**=!"=="!LINE!" (
if "!LINE:?=!"=="!LINE!" (
for %%I in ("!LINE:%_SEPCHR%=" "!") do (
endlocal
set "ITEM=%%~I"
call :PROCESS ITEM ITEM
setlocal EnableDelayedExpansion
for /F "delims=" %%C in (^""!COLL!!ITEM!%_SEPCHR%"^") do (
endlocal
set "COLL=%%~C"
setlocal EnableDelayedExpansion
)
)
) else set "COLL=%_SEPCHR%!LINE!%_SEPCHR%"
) else set "COLL=%_SEPCHR%!LINE!%_SEPCHR%"
set "COLL=!COLL:""="!^"
>> "%%~F" echo(!COLL:~1,-1!
endlocal
set "$HEADER="
)
)
endlocal
exit /B
:PROCESS rtn_string ref_string
setlocal EnableDelayedExpansion
set "#RET=%~1"
set "STR=!%~2!"
if not defined $HEADER (
if defined STR (
if "!STR:%_REPLAC%=!"=="!STR!" (
set "CHK=!STR:*%_SEARCH%=!%_SEARCH%"
set "CHK=!CHK:*%_SEARCH%=!"
if not defined CHK (
rem // Adapt regular expressions as needed:
(echo("!STR!" | > nul findstr /R ^
/C:"^\"[0-9]*\%_SEARCH%[0-9]*\" $" ^
/C:"^\"[+-][0-9]*\%_SEARCH%[0-9]*\" $" ^
/C:"^\"[0-9]*\%_SEARCH%[0-9]*[Ee][+-][0-9][0-9]*\" $" ^
/C:"^\"[+-][0-9]*\%_SEARCH%[0-9]*[Ee][+-][0-9][0-9]*\" $" ^
) && (
set "STR=!STR:%_SEARCH%=%_REPLAC%!"
)
)
)
)
)
for /F "delims=" %%S in (^""!STR!"^") do (
endlocal
set "%#RET%=%%~S"
)
exit /B

Answer 3

you can use this command :
$file = Get-Content c:\somewhere\file.csv |Out-String
$file.Replace(".",",") |Out-File c:\somewhere\file.csv