Access form record source not found after search - forms

Question

I have developed a split form which uses the following record source:
SELECT * FROM [CCG Complaints];
The form works well and I have no problems with that side of things.
Users have two buttons: one to search, and one to show all records.
The problems arise when, after performing a search, I close the form and then reopen it again (in form view):
However, whenever I click Show all before closing the form, it opens successfully in form view with no errors.
Another feature is that, after receiving the error mentioned above, I am able to open the form in design view, and can then view it in form view without the error message - the error only occurs when the form is opened in form view in the first instance.
Why is this and what can I do to rectify it?
The code I use for the buttons is here:
Private Sub search_Click()
Dim strSearch As String
Dim strText As String
If Len(Me.txtSearch.Value & vbNullString) = 0 Then
MsgBox ("Enter a search term.")
Else
strText = Me.txtSearch.Value
strSearch = "SELECT* from [CCG Complaints] where [Ref no] Like ""*" & strText & "*"" or [lastName] Like ""*" & strText & "*"" Or CCG Like ""*" & strText & "*"" "
Me.RecordSource = strSearch
End If
End Sub
Private Sub showAll_Click()
Dim strSearch As String
strSearch = "SELECT * from [CCG Complaints]"
Me.RecordSource = strSearch
End Sub

Answer 1

Instead of changing the recordsource, apply a filter to the existing records.
Me.filter = "[Ref no] Like ""*" & strText & "*"" or [lastName] Like ""*" & strText & "*"" Or CCG Like ""*" & strText & "*"" "
Me.FilterOn = True
Then Reset
Me.Filter = ""
Me.FilterOn = False
Be aware that if your record set gets even slightly large, this wildcard searching on lots of fields will become very inefficient. You might want to look at a more robust search method. This http://allenbrowne.com/ser-62.html is a more complete solution.

Answer 2

I suggest to set the RecordSource to [CCG Complaints], and not change it.
Instead use the .Filter properties, this is the usual way to implement a form filter:
Private Sub search_Click()
Dim strSearch As String
Dim strText As String
If Len(Me.txtSearch.Value & vbNullString) = 0 Then
MsgBox ("Enter a search term.")
Else
strText = Me.txtSearch.Value
strSearch = "[Ref no] Like ""*" & strText & "*"" or [lastName] Like ""*" & strText & "*"" Or CCG Like ""*" & strText & "*"" "
Me.Filter = strSearch
Me.FilterOn = True
End If
End Sub
Private Sub showAll_Click()
Me.Filter = ""
Me.FilterOn = False
End Sub