Gnuplot find local maximum of 3D data - sed

Question

I have a problem in gnuplot...
I am making an splot from my data points which are discrete "lines" (see attached pic) among y values of 1,1/2,1/3 etc...
At every discrete "line" I would like to get the maximum Z value and its X and Y coordinates, and highlight them, or maybe fitting a function on them etc...
Here is my code:
set title "1/m vs mutation rate"
#set term pdfcairo size 6,4
set term x11
set xlabel "Mutation rate"
set ylabel "1/m"
set xrange[0.0001:0.05]
set yrange[1.0/30:1]
unset log x
set cbrange[0:0.35]
set zrange[0:1]
set palette defined ( 0 "green", 1 "blue", 2 "red")
#set view 78,348,1,1
set view map
set output "muemmeres500map.pdf"
splot 'muemmeres500.txt' u 1:2:3 with points pt 5 ps 1 palette, "muemmeres500.txt" every 30 using ($3==GPVAL_DATA_Z_MAX?$1:NaN):($3==GPVAL_DATA_Z_MAX?$2:NaN):3 title "max1" lc rgb'black' lw 4, "muemmeres500.txt" every 30::2 using ($3==GPVAL_DATA_Z_MAX?$1:NaN):($3==GPVAL_DATA_Z_MAX?$2:NaN):3 title "max2" lc rgb'black' lw 4, "muemmeres500.txt" every 30::3 using ($3==GPVAL_DATA_Z_MAX?$1:NaN):($3==GPVAL_DATA_Z_MAX?$2:NaN):3 title "max3" lc rgb'black' lw 4, "muemmeres500.txt" every 30::4 using ($3==GPVAL_DATA_Z_MAX?$1:NaN):($3==GPVAL_DATA_Z_MAX?$2:NaN):3 title "max4" lc rgb'black' lw 4, "muemmeres500.txt" every 30::5 using ($3==GPVAL_DATA_Z_MAX?$1:NaN):($3==GPVAL_DATA_Z_MAX?$2:NaN):3 title "max5" lc rgb'black' lw 4
unset output
And here is the data file: http://pastebin.com/umqGWtyy
As you can see in the picture, the "lines" data points correspond to each line in the datafile, so for instance the data points starting with the first then every 30 correspond to the "line" which has a y value 1, then from the second line every 30 corresponds to the "line" which y value is 1/2 etc...
Therefore I wanted to get the maximum Z value from just those data...
I tried sed as well, but I failed...
So my problem is, that it can just find the global maxima and not the other local ones...:( pls help me:)
Here is the picture:
I have no idea... hope it is understandable and sorry for my english...:)

Answer 1

GPVAL_DATA_Z_MAX doesn't seem to work for your problem but you can use stats instead to find all the local maxima and then plot them all in a looped plot.
#Do it before setting the ranges (the column will be handled as an x column and it might get out of xrange)
do for [i=0:28]{
#Give an indexed prefix to each stat (so they *all* become accessible from outside the loop, like "A12_max" or "A25_min")
stats 'muemmeres500.txt' every 30::i u 3 nooutput prefix "A".i
}
#set all the things you need for the plot (including ranges)
...
splot 'muemmeres500.txt' u 1:2:3 with points pt 5 ps 1 palette, \
for [i=0:28] '' every 30::i u 1:2:($3==value("A".i."_max") ? $3 : NaN) notitle #t "Max".(i+1)
Note: the indices used by every start from zero.
This only works for plotting, you have all the maxima but you don't have the X and Y coordinates yet.
You also have the indices of the maxima so if you can retrieve the X Y values from the A<n>_index_max row (actually its 30*index+i or the nth block's ith row ) you have the nth maximum position. To retrieve the nth row you can use stats again with every.
do for [i=0:28]{
stats 'muemmeres500.txt' every ::i:value("A".i."_index_max"):i:value("A".i."_index_max") u 1:2 nooutput prefix "P".i
}
If you do this right after getting the Ai_ stats you already have all the positions P<i>_max_x P<i>_max_y and Z values A<i>_max.
If you want you can print them to a file:
set print "maxima.dat"
do for [i=0:28]{
print value("P".i."_max_x"), (value("P".i."_max_y")), (value("A".i."_max"))
}
unset print