egen tag skipping - tags

Question

I want to tag new occurrences of a new agent_type. I use the following code to do this:
clear
input long patid float(how_many_drugs agent_type eventdate) byte tag4
01 3 4 14962 1
01 3 5 14962 1
01 3 4 14997 0
01 3 9 14997 0
01 3 5 15025 0
01 3 9 15040 1
01 3 4 15040 0
01 3 5 15082 0
end
format %td eventdate
label values agent_type drugstypes1
label def drugstypes1 4 "alpha blocker", modify
label def drugstypes1 5 "ace_inhib", modify
label def drugstypes1 9 "loop", modify
label def drugstypes1 13 "CCB", modify
egen tag4=tag (patid agent_type_new how_many_drugs)
The code works fine, until we reach the first occurrence of "loop" where a tag is NOT generated. Rather, the tag is generated on the second occurrence of "loop".
Why is this happening and how can I make it work to make a tag on first occurrence?
I have made sure that the data were sorted by patid event_date before running the tag code.

Answer 1

As the original author of this egen function tag(), I can comment on its intent.
The intent is not to tag first occurrences as such. The intent is to tag just one of several occurrences which so far as the user is concerned are equivalent.
As it happens, there are only two systematic ways to tag equivalent occurrences, to tag the first or the last. As groups could be as small as one observation, any rule must work on groups that small. For groups of one, choosing the first is the same as choosing the last, but otherwise that is not so. I chose to tag the first in the original code (long since adopted into official Stata), but that is arbitrary.
So why this is happening to you? The function feels totally free to re-sort the data temporarily, as looking at the code will show you:
viewsource _gtag.ado
This is what is biting.
You want to tag the first occurrences of each distinct value of each drug type for each patient. That is one line, as at bottom. I don't understand why how_many_drugs is used in your code.
clear
input long patid float(how_many_drugs agent_type eventdate) byte tag4
01 3 4 14962 1
01 3 5 14962 1
01 3 4 14997 0
01 3 9 14997 0
01 3 5 15025 0
01 3 9 15040 1
01 3 4 15040 0
01 3 5 15082 0
end
format %td eventdate
label values agent_type drugstypes1
label def drugstypes1 4 "alpha blocker", modify
label def drugstypes1 5 "ace_inhib", modify
label def drugstypes1 9 "loop", modify
label def drugstypes1 13 "CCB", modify
bysort patid agent_type (eventdate) : gen first = _n == 1

Answer 2

I've been playing with this for a little while, and in the end abandoned egen tag(). I couldn't understand why it wouldn't pick up the first occurrence of every agent_type so instead I've opted for this:
bys patid agent_type (eventdate): gen n=_n
sort patid eventdate
replace n=0 if n!=1