How to use BLAS functions in Fortran mex files - matlab

Question

I've tried to use BLAS functions in my Fortran mex file, but it didn't work. Here's an example of one of my code that uses DGEMM:
#include "fintrf.h"
C Gateway subroutine
subroutine mexfunction(nlhs, plhs, nrhs, prhs)
C Declarations
implicit none
C mexFunction arguments:
mwPointer plhs(*), prhs(*)
integer nlhs, nrhs
C Function declarations:
mwPointer mxGetPr
mwPointer mxCreateDoubleMatrix
mwsize mxGetM,mxGetN
C Pointers to input/output mxArrays:
mwPointer pr_A, pr_B, pr_C
mwSize :: sizea,sizeb
C Array information:
real*8, allocatable :: A(:,:),B(:,:),C(:,:)
C Get the size of the input array.
sizea = mxGetM(prhs(1))
sizeb = mxGetN(prhs(2))
allocate(A(sizea,sizea),B(sizea,sizeb),C(sizea,sizeb))
C Create Fortran array from the input argument.
pr_A = mxGetPr(prhs(1))
pr_B = mxGetPr(prhs(2))
call mxCopyPtrToReal8( pr_A, A, sizea**2 )
call mxCopyPtrToReal8( pr_B, B, sizea*sizeb )
call MUL(A,B,C,sizea,sizeb)
C Create matrix for the return argument.
plhs(1) = mxCreateDoubleMatrix(sizea, sizeb, 0)
pr_C = mxGetPr(plhs(1))
call mxCopyReal8ToPtr(C , pr_C, sizea*sizeb )
return
end
subroutine MUL(A,B,C,sizea,sizeb)
implicit none
mwSize :: sizea,sizeb
real*8 :: A(sizea,sizea),B(sizea,sizeb),C(sizea,sizeb),alpha,beta
integer*4 :: M,N,K
character ch1, ch2
ch1 = 'N'
ch2 = 'N'
M=size(A,1)
N=size(B,2)
K=size(A,2)
Alpha=1.
Beta=0.
CALL DGEMM(ch1,ch2,M,N,K,ALPHA,A,M,B,K,BETA,C,M)
return
end subroutine MUL
I use the following line to create a mex file:
mex -lmwblas Test.F
The mex file builds without any error, but when I try to use the function, matlab closes without any error message. I'm using Matlab R2016a with Intel Visual Fortran Composer XE 2013 with Microsoft Visual Studio 2012.

Answer 1

You do not call DGEMM correctly. All of your arguments are real*8 but many of them are supposed to be integers.
Check thoroughly the documentation of DGEMM and check your call argument after argument to follow the interface exactly. I am pretty convinced passing the value of 1 instead of the sizea for K is wrong as well. But really, you have to check each and every argument.
I suggest to test your subroutines in pure Fortran and only after they work correctly use them from Matlab.

Answer 2

here's the solution:
#include "fintrf.h"
C Gateway subroutine
subroutine mexfunction(nlhs, plhs, nrhs, prhs)
C Declarations
implicit none
C mexFunction arguments:
mwPointer plhs(*), prhs(*)
integer nlhs, nrhs
C Function declarations:
mwPointer mxGetPr
mwPointer mxCreateDoubleMatrix
mwsize mxGetM,mxGetN
C Pointers to input/output mxArrays:
mwPointer pr_A, pr_B, pr_C
mwSignedIndex :: sizea,sizeb
C Array information:
real*8, allocatable :: A(:,:),B(:,:),C(:,:)
C Get the size of the input array.
sizea = mxGetM(prhs(1))
sizeb = mxGetN(prhs(2))
allocate(A(sizea,sizea),B(sizea,sizeb),C(sizea,sizeb))
C Create Fortran array from the input argument.
pr_A = mxGetPr(prhs(1))
pr_B = mxGetPr(prhs(2))
call mxCopyPtrToReal8( pr_A, A, sizea**2 )
call mxCopyPtrToReal8( pr_B, B, sizea*sizeb )
call MUL(A,B,C,sizea,sizeb)
C Create matrix for the return argument.
plhs(1) = mxCreateDoubleMatrix(sizea, sizeb, 0)
pr_C = mxGetPr(plhs(1))
call mxCopyReal8ToPtr(C , pr_C, sizea*sizeb )
return
end
subroutine MUL(A,B,C,sizea,sizeb)
implicit none
mwSignedIndex :: sizea,sizeb
real*8 :: A(sizea,sizea),B(sizea,sizeb),C(sizea,sizeb),alpha,beta
mwSignedIndex :: M,N,K
character ch1, ch2
ch1 = 'N'
ch2 = 'N'
M=size(A,1)
N=size(B,2)
K=size(A,2)
Alpha=1.0
Beta=0.0
CALL DGEMM(ch1,ch2,M,N,K,ALPHA,A,M,B,K,BETA,C,M)
return
end subroutine MUL
and to build the mex file use
mex -largeArrayDims -lmwblas Test.F