How to print code embedded in a here-doc to lexical filehandle - perl

Question

I'm trying to create a script that will generate perl code from a template, and I'm having trouble understanding the error being thrown and why my workaround fixes it.
This example is contrived, but it demonstrates the issue:
use strict;
use warnings;
my $name = shift; # from #ARGV
my $file = sprintf "%s.pm", $name;
open my $fh, ">", $file
or die "error: open(>, '$file'): $!";
print $fh << "MODULE";
package $name;
#
# blah blah
#
use strict;
use warnings;
require Exporter;
our \#ISA = qw| Exporter |;
our \#EXPORT = qw| |; # automatic exports
our \#EXPORT_OK = qw| |; # on-demand exports
# CODE
1;
MODULE
close $fh;
When running this script, I get the following error:
$ perl script.pl Foo
Invalid version format (non-numeric data) at script.pl line 11, near "package "
syntax error at script.pl line 11, near "package $name"
BEGIN not safe after errors--compilation aborted at script.pl line 17.
Originally this script was just printing to stdout instead of writing to file -- no errors thrown. After adding the file handling and receiving this error, I then tried to just use a bare filehandle -- again no errors thrown.
So if I merely replace "$fh" with "FH" everywhere, the script works as expected. What is it about the lexical filehandle causing this to choke?

Answer 1

There should be no space after << marking the here document, so
print $fh << "MODULE";
should be
print $fh <<"MODULE";
or more neatly
print $fh <<MODULE;
or perhaps
print $fh (<< "MODULE");
As it is the << is being treated as a left-shift operator and Perl continues to try to compile the package statement. Finding no valid package name it tries to use $nameas a version number, and complains because it isn't one

Answer 2

Perl is an ambiguous language. It means that it's not always clear how it should be parsed. In some situations, perl has to guess how to parse something. There's a grammatical ambiguity in
print $fh << "MODULE";
Specifically, the << can be a left shift operator or the start of here-doc.
There are two paths you can follow to address the issue.
You can remove the ambiguity:
print $fh +<< "MODULE";
print $fh (<< "MODULE");
print { $fh } << "MODULE";
$fh->print(<< "MODULE");
You can trick perl into guessing correctly:
print $fh <<"MODULE";
Note that print $fh +<< "MODULE"; introduces an alternate ambiguity. Is + a binary or unary + operator? Thankfully, it's interpreted as a unary-+ as desired.
By the way, <<"MODULE" can be shortened to <<MODULE.