How to duplicate folder then rename folder and files inside it in Batch or Powershell to multiple folders [closed] - powershell

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 5 years ago.
Improve this question
Let's say I have this folder structure:
02548 //let's call this MASTER FOLDER, folder name are using site_id
|- 1. Master File
|- 02548_MSFI.pdf
|- 2. src
|- 02548_main.cpp
|- 3. Backup
|- alpha.svn
I also have site_id.txt file contains the name of side_id:
02548
03584
05482
07992
05861
What I want to do is to duplicate the MASTER FOLDER to new folders. So, the final result will be something like this:
|-02548 // MASTER FOLDER
| |- 1. Master File
| |- 02548_MSFI.pdf
| |- 2. src
| |- 02548_main.cpp
| |- 3. Backup
| |- alpha.svn
|-03584 //the folder name are taken from the list inside the site_id.txt
| |- 1. Master File
| |- 03584_MSFI.pdf //please notice the prefix of this file's name
| |- 2. src
| |- 03584_main.cpp //please notice the prefix of this file's name
| |- 3. Backup
| |- alpha.svn
|-05482 //the folder name are taken from the list inside the site_id.txt
| |- 1. Master File
| |- 05482_MSFI.pdf //please notice the prefix of this file's name
| |- 2. src
| |- 05482_main.cpp //please notice the prefix of this file's name
| |- 3. Backup
| |- alpha.svn
and so on until all the site_id from site_id.txt are here.
In the real world, site_id.txt will contains more than 1000 of list. So, doing this manually will be very painful.
How do I do this using batch script or powershell?

Answer 1

Don't know how you would do it, but this is how I would do it if I had a job and that task was assigned to me:
#ECHO OFF
SETLOCAL
SET "sourcedir=U:\sourcedir"
SET "destdir=U:\destdir"
SET "filename1=%sourcedir%\q44093158.txt"
FOR /f "usebackqdelims=" %%a IN ("%filename1%") DO (
XCOPY /s /e "%sourcedir%\t w o\*" "%destdir%\%%a\" >nul
FOR /f "delims=" %%p IN ('dir /s /b "%destdir%\%%a\*#*"') DO (
SET "filename=%%~nxp"
CALL set "filename=%%filename:#=%%a%%"
CALL REN "%%p" "%%filename%%"
)
)
GOTO :EOF
You would need to change the settings of sourcedir and destdir to suit your circumstances.
I used a file named q44093158.txt containing your data for my testing.
Within the source directory, (I actually tested with \t w o appended to ensure it worked with directorynames containing spaces), build the structure including the master files with the branch-number replaced by #
The code simply reads filename1 which contains the branch names one to a line, duplicates the directory structure at the destination, then looks for filenames containing #. With those files, it substitutes the branch name for the # and renames the file.
Done!

Answer 2

This PowerShell script and the file site_id.txt should be placed in the parent folder of 02548
## C:\Test\Copy-Template.ps1
$template = '02548'
foreach ($site in (Get-Content site_id.txt)) {
Get-ChildItem $template -recurse | Foreach-Object {
$NewName = $_.FullName -replace $template,$site
if ($_.PSIsContainer){
if (!(Test-path $NewName)){md $NewName|Out-Null}
} else {
copy $_.FullName $NewName -EA 0
}
}
}
Sample output:
> tree /F
C:.
│ Copy-Template.ps1
│ site_id.txt
│
└───02548
├───1. Master File
│ 02548_MSFI.pdf
│
├───2. src
│ 02548_main.cpp
│
└───3. Backup
alpha.svn
> .\Copy-Template.ps1
> tree /f
C:.
│ Copy-Template.ps1
│ site_id.txt
│
├───02548
│ ├───1. Master File
│ │ 02548_MSFI.pdf
│ │
│ ├───2. src
│ │ 02548_main.cpp
│ │
│ └───3. Backup
│ alpha.svn
│
├───03584
│ ├───1. Master File
│ │ 03584_MSFI.pdf
│ │
│ ├───2. src
│ │ 03584_main.cpp
│ │
│ └───3. Backup
│ alpha.svn
│
├───05482
...
├───05861
...
└───07992
├───1. Master File
│ 07992_MSFI.pdf
│
├───2. src
│ 07992_main.cpp
│
└───3. Backup
alpha.svn

Answer 3

#echo off
setlocal EnableDelayedExpansion
rem Call the subroutine, read data from site_id file
call :DuplicateTree < site_id.txt
goto :EOF
:DuplicateTree
rem Read MasterFolder from first line
set /P "masterFolder="
:nextFolder
rem Read and process next folders until EOF
set /P "nextFolder="
if errorlevel 1 exit /B
rem Duplicate folders first
md "%nextFolder%"
for /R "%masterFolder%" /D %%a in (*) do (
set "folder=%%a"
set "folder=!folder:*%cd%\=!"
md "!folder:%masterFolder%=%nextFolder%!"
)
rem Duplicate files
for /R "%masterFolder%" %%a in (*) do (
set "file=%%a"
set "file=!file:*%cd%\=!"
copy "%%a" "!file:%masterFolder%=%nextFolder%!"
)
goto nextFolder
Place this Batch file in the same folder that contain both site_id.txt file and 02548 Master Folder.