SAS: Write a macro... - macros

Question

I am having a question on SAS Macro (I do analytics in R and python, No SAS). SO, it is getting me into some lack of understanding in syntax of SAS in solving the following question.
Write a macro that accepts a table name, a column name, a list of integers, a main axis label and an x axis label. This function should scan over each element in the list of integers and produce a histogram for each integer value, setting the bin count to the element in the input list, and labeling main and x-axis with the specified parameters. You should label the y-axis to read Frequency, bins = and the number of bins.
Also I need to test macro with a data set, using bin numbers 12, 36, and 60. So, that I am able to call macro with something like
%plot_histograms(data, y, 12 36 60, main="Title", xlabel="x_label");
to plot three different histograms of the data set.
Hint: Assume 12 36 60 resolve to a single macro parameter and use %scan, macro definition can look something like
%macro plot_histograms(table_name, column_name, number_of_bins, main="Main", xlabel="X Label")
Thanks in Advance.

Answer 1

I don't fully understand your question and this is not a free code platform anyway but this should point you in the right direction
%macro plot_histograms(table_name, column_name, number_of_bins, main="Main", xlabel="X Label");
%do i=1 %to %sysfunc(countw(&number_of_bins.); /* loop accross elements in your input list */
proc gchart data=&table_name.; /*make a chart for the provided table */
...
/* whatever it is you actually need to do, fetch the current element of the input list like this */
%scan(&number_of_bins.,&i.)
...
run;
%end;
%mend;

Answer 2

First, you really should try this on your own and let us know where you get stuck.
That said, let's break down how to solve this problem.
Make some test data;
data test;
do i=1 to 10000;
r = rannor(1);
output;
end;
run;
How do I create a histogram with this? Use PROC SGPLOT
proc sgplot data=test;
histogram r / nbins=10;
xaxis label="X LABEL";
yaxis label="Y LABEL";
run;
Produces this:
So, if I make a macro to create this generally:
%macro histogram(data,column,bin,xlabel,ylabel);
proc sgplot data=&data;
histogram &column / nbins=&bin;
xaxis label="&xlabel";
yaxis label="&ylabel";
run;
%mend;
Now %histogram(test,r,10,X LABEL,Y LABEL)' produces the same image.
Let's write something that loops over the values of bins and call this macro:
%macro make_histograms(data,column,bins,xlabel,ylabel);
%local i n bin;
%let n=%sysfunc(countw(&bins)); /*Number of words in &bins*/
%do i=1 %to &n;
%let bin=%scan(&bins,&i); /*Get the nth bin*/
%histogram(&data,&column,&bin,&xlabel,&ylabel);
%end;
%mend;