how to save multiple summary files batch process macro imageJ - macros

Question

I am pretty new to batch image processing in imageJ. I have a macro that allows me to process several images in a single directory. The problem is that the macro generates an individual summary window for each processed image, leaving me to manually compile all the output data into a single .csv or .xls. I would prefer that all the summary data be automatically compiled into one file. While I have found several sources showing how to do this, it has not been particularly helpful in my situation.
If you could help, I'd be very grateful.
Here is an abbreviated example of the code:
dir1 = getDirectory("Choose Source Directory ");
dir2 = getDirectory("Choose Destination directory");
list = getFileList(dir1);
setBatchMode(true);
for (i=0; i<list.length; i++){
print (list[i]);
open(dir1+list[i]);
name=File.nameWithoutExtension;
//Prepare the image by removing any scale and making 8-bit
run("Set Scale...", "distance=237.3933 known=1 pixel=1 unit=cm
global");
makeRectangle(4068, 5940, 1572, 1320);
run("Crop");
// Convert the image into RGB channels for proper thresholding
run("RGB Stack");
setSlice(3);
//Threshold
setAutoThreshold("Default");
// Analyze particles
// Provides total area of number of cotyledons in image
run("Analyze Particles...", "size=60-Infinity pixel display include
summarize");
run("Revert");
}
//Save the results
selectWindow("Summary");
saveAs("Results", dir2+"Results.xls");

Answer 1

In my tests (with ImageJ 2.0.0-rc-61/1.51n on macOS 10.12.6), repeatedly executing Analyze Particles with the summarize option checked appends the summary to the existing Summary window, which can then be saved as a single file at the end.
For example, the following macro generates two summary lines and then saves them:
setBatchMode(true);
run("Blobs (25K)");
setAutoThreshold("Default");
run("Analyze Particles...", "size=60-Infinity pixel display include summarize");
run("Boats (356K)");
setAutoThreshold("Default");
run("Analyze Particles...", "size=60-Infinity pixel display include summarize");
selectWindow("Summary");
saveAs("Results", "/Users/curtis/Desktop/Results.xls");