Find the path of an application, and copy a file to that directory in Inno Setup - matlab

Question

I'd like to install a file into a user's MATLAB folder in Inno Setup. But depending on the version of MATLAB, the directory can change.
In the Windows command line, it is possible to get the path of the MATLAB executable like so:
where matlab
Which will output
C:\Program Files (x86)\MATLAB\R2015b\bin\matlab.exe
I'd like to copy a file in the following folder
C:\Program Files (x86)\MATLAB\R2015b\toolbox\local
How can this be done?

Answer 1

The where command searches the file in the path specified by the PATH environment variable.
In Inno Setup Pascal Script, you can implement that using FileSearch function, like:
FileSearch('matlab.exe', GetEnv('PATH'))
Though I'd say, that there's must be a better way to find installation folder of MATLAB.
Anyway, you can resolve the path using the above method to a global variable in InitializeSetup event function. It will also allow you to abort the installation, when MATLAB is not found.
And then you can use the variable as an installation path using a scripted constant.
[Files]
Source: "MyFile.dat"; DestDir: "{code:GetMatlabToolboxLocalPath}"
[Code]
var
MatlabToolboxLocalPath: string;
function GetMatlabToolboxLocalPath(Param: string): string;
begin
Result := MatlabToolboxLocalPath;
end;
function InitializeSetup(): Boolean;
var
MatlabExePath: string;
begin
MatlabExePath := FileSearch('matlab.exe', GetEnv('PATH'));
if MatlabExePath = '' then
begin
MsgBox('Cannot find MATLAB', mbError, MB_OK);
Result := False;
Exit;
end;
MatlabToolboxLocalPath := ExtractFilePath(MatlabExePath) + '..\toolbox\local';
Result := True;
end;