substring match in perl, yes or no - perl

Question

With perl, I want to find a substring in a string. The result is a True/False and then I will decide what to do. There is good post here, but the usage is vague for me.
my $big_string = "Hello Good World";
my $pat = "world";
While the capital/non-capital letters are not important, I want to get True.
use List::Util 'any';
my $match_found = any { /$pat/ } #big_string;
if (match_found)
print "yes\n";
else
print "no\n";
Is that correct? Is there any better API for this purpose?

Answer 1

It's not correct because it doesn't even compile: if / else are always followed by a { } block in Perl. Also, if (match_found) is missing the $ sigil on the variable.
If you really want case insensitive matching (i.e. to ignore the differences between uppercase and lowercase letters), you need to add the i flag to the regex.
Finally, your code doesn't define a #big_string array, only a $big_string scalar.
So:
use strict;
use warnings;
use List::Util 'any';
my $big_string = "Hello Good World";
my $pat = "world";
my $match_found = any { /$pat/i } $big_string;
if ($match_found) {
print "yes\n";
} else {
print "no\n";
}
This code would work, but it can be improved.
First off, why use any at all? We don't have a list of multiple strings to check:
my $match_found = $big_string =~ /$pat/i;
Second, $pat doesn't look like it's supposed to be a regex. It's a plain string. This doesn't make any difference for alphanumeric characters (such as world), but in general we should escape all regex metacharacters in strings that aren't intended to be interpreted as regexes. This can be done with the quotemeta function (or its \Q \E short form):
my $match_found = $big_string =~ /\Q$pat\E/i;
This is our improved version:
use strict;
use warnings;
my $big_string = "Hello Good World";
my $pat = "world";
my $match_found = $big_string =~ /\Q$pat\E/i;
if ($match_found) {
print "yes\n";
} else {
print "no\n";
}
Finally, we don't even need a regex for a simple substring search. Instead we can do this:
use feature 'fc';
my $match_found = index(fc($big_string), fc($pat)) >= 0;
fc implements full Unicode case folding.