Sorting hashof array of datetime string in Perl - perl

Question

I was trying to sort datetimes in Perl. The datetime string is in a hash of arrays. After lots of googling I used Perl's sort function. To my surprise it worked. My code & input is below:
use strict;
use warnings;
my %hashofarrays;
$hashofarrays{'joe tribiani'} = ['16/3/28 13:42','XII','99.93%'];
$hashofarrays{'Ross'} = ['16/3/28 13:43','XII','76.93%'];
$hashofarrays{'sue grace'} = ['11/7/5 12:07','VI','77.58%'];
foreach my $key ( sort{$hashofarrays{$a}[0] cmp $hashofarrays{$b}[0]} keys %hashofarrays ) {
print "$key =>", join (", ", #{$hashofarrays{$key}}), "\n";
}
Am I doing this correctly? If I am, how is this working?
If it is wrong then what should I do to sort the date time string?
The result should list records sorted in ascending order by datetime.
The datetime format is 'YY/MM/DD' or 'YY/M/D'
My data:
joe tribiani, 16/3/28 13:42,XII,99.93%
Ross,16/3/28 13:43,XII,95.93%
sue grace,11/7/5 12:07,VI,77.58%
My excepted output:
sue grace =>11/7/5 12:07, VI, 77.58%
joe tribiani =>16/3/28 13:42, XII, 99.93%
Ross =>16/3/28 13:43, XII, 76.93%

Answer 1

What your code does
foreach my $key (
sort { $hashofarrays{$a}[0] cmp $hashofarrays{$b}[0] }
keys %hashofarrays
) {
print "$key =>", join (", ", #{$hashofarrays{$key}}), "\n";
}
This uses the keys of the hash to sort the elements of the hash on the first element of the array reference that's inside of that key in the hash. It uses cmp, which is an ascii-betical sorting rather than a numerical one. That means that 10 will come before 2 because 1 is a lower character than 2.
For date sorting, this makes sense. But because your date format is not consistently with two digits for months and days, it will not sort properly.
18/5/1 # sorted last
18/10/1 # sorted first
For those two dates, the later October date will be sorted first which is wrong.
What you need to do instead
If you cannot clean up the input data, you need to process it to figure out the value behind the date instead of relying on the presentation for sorting. Parsing dates is its own problem, and we'll use Time::Piece to do it, which has been in the Perl core for a while now.
We could do it like this pseudo-code:
sort { parse($a) <=> parse($b) } ...
That would work, but would be slow, especially for a larger number of records, because it parses the date with every comparison. If you don't know how sorting works internally, it compares values to each other, maybe changes position of the two values, and repeats.
There is a way of making this more efficient, but it's a bit more complex.
use strict;
use warnings;
use Time::Piece;
my %values = ( 'joe tribiani' => [ '16/3/28 13:42', 'XII', '99.93%' ],
'Ross' => [ '16/3/28 13:43', 'XII', '76.93%' ],
'sue grace' => [ '11/7/5 12:07', 'VI', '77.58%' ], );
my #sorted_keys = map { $_->[1] }
sort { $a->[0] <=> $b->[0] }
map {
[ Time::Piece->strptime( $values{$_}->[0], '%y/%m/%d %H:%M' )->epoch, $_ ]
}
keys %values;
use Data::Dumper;
print Dumper #sorted_keys;
This is called the Schwartzian transform. It essentially processes the values once, puts them into another array reference, together with the actual values that are being sorted. It then sorts on the pre-processed values, and then puts them back.
This is way more efficient, and because of the parsing it will work on all dates that might show up in your values without sorting them in the wrong way.
Note we need to use the numerical comparison operator <=> now, because we are sorting on epoch values, which are just numbers (lots of seconds from 1970-01-01T00:00:00).