How can I determine IP address of a workstation logged into a windows server from vb6 code - sql-server-2008-r2

Question

I have a VB6 program that is multi-user and runs on a network. Some users are on Windows XP Desktops and some are on Thin clients logging in to a Windows 2008R2 Server using RDP. I have a new requirement which requires that I know the IP addresses of the users on the Local Area Network, and the IP of the remote users, or the login of the remote users. I am not sure this is even possible. Any help or information would be greatly appreciated.

Answer 1

This returns current RDP session's client IP address or an empty string when not executed under RDP session.
Client IP address is one of the local IPs of the client machine as reported by the mstsc.exe upon establishing connection and might differ from the real IPs observed with netstat or similar.
Option Explicit
'--- for WTSQuerySessionInformation
Private Const WTS_CURRENT_SERVER_HANDLE As Long = 0
Private Const WTS_CURRENT_SESSION As Long = -1
Private Const WTSClientAddress As Long = 14
'--- for AddressFamily
Private Const AF_INET As Long = 2
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (lpvDest As Any, lpvSource As Any, ByVal cbCopy As Long)
Private Declare Function WTSQuerySessionInformation Lib "wtsapi32" Alias "WTSQuerySessionInformationA" (ByVal hServer As Long, ByVal SessionId As Long, ByVal WtsInfoClass As Long, ppBuffer As Long, pBytesReturned As Long) As Long
Private Declare Sub WTSFreeMemory Lib "wtsapi32" (ByVal pMemory As Long)
Private Type WTS_CLIENT_ADDRESS
AddressFamily As Long
Address(0 To 19) As Byte
End Type
Private Function GetSessionClientIp() As String
Dim uAddress As WTS_CLIENT_ADDRESS
Dim lPtr As Long
Dim lSize As Long
Call WTSQuerySessionInformation(WTS_CURRENT_SERVER_HANDLE, WTS_CURRENT_SESSION, WTSClientAddress, lPtr, lSize)
If lSize >= LenB(uAddress) Then
Call CopyMemory(uAddress, ByVal lPtr, LenB(uAddress))
End If
Call WTSFreeMemory(lPtr)
If uAddress.AddressFamily = AF_INET Then
GetSessionClientIp = uAddress.Address(2) & "." & uAddress.Address(3) & "." & uAddress.Address(4) & "." & uAddress.Address(5)
End If
End Function
Private Sub Form_Load()
MsgBox "GetSessionClientIp=" & GetSessionClientIp(), vbExclamation
End Sub