Changing value in if statement - numbers

Question

I'm trying to iterate through a column in numbers and change the background color of a cell, if the cell has a certain background color.
repeat with i from 11 to the count of cells by 6
if background color of cell i is {17990, 47031, 42919} then
set background color of cell i to {65535, 0, 0}
end if
end repeat
unfortunately, this does not do anything. The script just stops without Error. Help please!

Answer 1

There seems to be a bug in Numbers app where is not reporting the colors correctly. I set the background colors of columns A and B to your chosen value {17990, 47031, 42919}, but when I asked the script to return the colors, it returned the value {17990, 47030, 42919}. Because of this, I had the script check for both values and to act accordingly.
I added a dialog pop-up giving you the option to choose which column to change the cell colors.
tell application "Numbers"
set ifColor to {17990, 47031, 42919}
set ifColor2 to {17990, 47030, 42919}
set changeToColor to {65535, 0, 0}
tell its document 1
set theColumns to name of columns of table "Table 1" of active sheet
set chosenColumn to item 1 of (choose from list theColumns with title "Choose The Column" with prompt "Choose The Column")
set cellCount to count of cells of column chosenColumn of table "Table 1" of active sheet
repeat with i from 11 to cellCount by 6
set thisCell to cell ((chosenColumn & i) as string) of table "Table 1" of active sheet
if background color of thisCell is ifColor or background color of thisCell is ifColor2 then
set background color of thisCell to changeToColor
end if
end repeat
end tell
end tell

Answer 2

Here's the table I started with, having coloured the background of one cell magenta, i.e. {65535,0,65535}.
Then I ran this code:
use NumbersApp : application "Numbers"
property document : a reference to document 1 of NumbersApp
property sheet : a reference to active sheet of my document
property table : a reference to table 1 of my sheet
repeat with c in (a reference to every cell of my table)
if c's background color = missing value then ¬
set c's background color to {65535, 65535, 0}
if c's background color = {65535, 0, 65535} then ¬
set c's background color to {65535, 65535, 65535}
end repeat
I was expecting the majority of cells to turn yellow, and my magenta cell to turn white:
Hm...
My magenta cell is still looking far too magenta. So I decided to check just how magenta it really is:
return the background color of cell "C7" of my table
--> {64587, 609, 65480}
Well, that's not what I set it to, but it's pretty magenta, though I now see why it didn't turn white.
Next I decided to check the background colour of one of the yellow cells, that you have just seen me programmatically turn to a very specific kind of yellow:
return the background color of cell "D10" in my table
--> {65534, 65531, 2689}
Again, it is yellow, but not the yellow I told it to be.
Finally, I used the colour value just returned to try and target those cells and turn them black:
set the background color of every cell in my table ¬
whose background color is {65534, 65531, 2689} ¬
to {0, 0, 0}
Zilch. They are still very sunnily yellow.
Conclusion
Bug in AppleScript. I've submitted a bug report to Apple. I suggest you do the same.

Answer 3

#wch1zpink: {17990, 47031, 42919} --> {17990, 47030, 42919}
Looks like a rounding error introduced when converting integers to floating point numbers and back again. (AppleScript dates from the days of QuickDraw, which represented RGB values as UInt16, whereas Numbers is a Cocoa app, and Cocoa's NSColor uses CGFloat.) That's unavoidable, being a fundamental limitation of how CPUs do math (e.g. 0.7 * 0.7 = 0.49 --> false!).
The solution is to check the numbers are equal within an acceptable margin of error:
on areRealsEqual(n1, n2, toleranceMargin)
return n1 > n2 - toleranceMargin and n1 < n2 + toleranceMargin
end areRealsEqual
on areColorsEqual(c1, c2)
repeat with i from 1 to length of c1
if not areRealsEqual(item i of c1, item i of c2, 5) then return false
end repeat
return true
end areColorsEqual
set expectedColor to {17990, 47031, 42919}
set foundColor to {17990, 47030, 42919}
areColorsEqual(expectedColor, foundColor)
--> true