calling a function and its arguments from a table in q - kdb

Question

I am trying to call a function and its arguments from a table. So I call the function by:
(first exec function from table where id=jobId)
In this example I get: +
Then I call the arguments as:
[first exec args from table where id=jobId]
and I get as an example [2 2]
Running the two lines after each other as:
`(first exec func from table where id=jobId)[first exec args from .table where id=jobId]`
Will give me: +[2 2]
But I need: +[2;2].
I am reading this statement from the documentations but I could not quite implement.
"
Arguments to the functional form of exec (?[;;;]) must be passed in parsed form and, depending upon the desired results, in a particular data structure. "
I tried to convert the passing of the arguments part into a functional call like this:
?[table;jobId=id;args;()]

Answer 1

To cover the general case of functions with single inputs, multiple inputs etc you'd need something like:
q)t:([]func:({x+1};floor;{x+y};first;{x+100});args:(12;1.5;2 2;"abc";`foo))
q)t
func args
-------------
{x+1} 12
_: 1.5
{x+y} 2 2
*: "abc"
{x+100} `foo
q)update res:{.[x;(),y;#[x;y;]`$]}'[func;args] from t
func args res
-------------------
{x+1} 12 13
_: 1.5 1
{x+y} 2 2 4
*: "abc" "a"
{x+100} `foo `type

Answer 2

To call your function and arguments from a table, you can use a . apply, like so:
q)table:([] function:+;args:enlist 2 2;id:1)
q)table
function args id
----------------
+ 2 2 1
q)exec .[first function;first args] from table where id=1
4
Hope this helps.

Answer 3

If you are trying to execute function on arguments then you could directly do that inside select/exec statement.
q) exec function .' args from table where id=1

Answer 4

I'm supposing that your table looks something like this
q)show table:([] function:(+;*;{x+2*y}); args:(2 2;9 7;1 3); id:0 1 2)
function args id
----------------
+ 2 2 0
* 9 7 1
{x+2*y} 1 3 2
When you have your function and arguments you can apply using .(apply):
q)jobId:1
q)(first exec function from table where id=jobId) . first exec args from table where id=jobId
63
You can simplify the query above to exec only once if you use the '(each-both) adverb:
q)first exec function .' args from table where id=1
63
And if you drop the where clause above you can get the result off applying each function to each of its arguments:
q)update result:function .' args from table
function args id result
-----------------------
+ 2 2 0 4
* 9 7 1 63
{x+2*y} 1 3 2 7