problem to read line after the first string match - perl

Question

Not sure why this script isn't working. Can anyone suggest a fix in order to get the expected output?
Perl script:
open(INFILE,"test_input.txt")||die "can't open the file";
while(<INFILE>){
$_=~s/^\s+//;
$_=~s/\s+$//;
if ($_ =~ /work/){
<INFILE> or die "Bad file format";
my $model = INFILE;
print "line below search: $model\n";
if ($model =~/^good/){
print "found good word\n";
}
else{
print "no good word\n";
}
}
}
input file:
employment
work hard
good people
Expected Output:
line below search: good people
found good word
Actual Output:
line below search:
no good word

Answer 1

You were very close. To get your program running as you expected, I only had to make a couple of changes.
You have this code:
<INFILE> or die "Bad file format";
my $model = INFILE;
I think you're trying to ensure that there is actually another line after the one you've matched. But in the first of those lines, you just read the next line and throw the data away. And in the second of those lines, you set $model to the string "INLINE". Perhaps you meant my $model = <INFILE> - but even that doesn't give you what you want as you've already read (and discarded) the record you want in the previous line of code.
So I think you want to replace those two lines with a single line.
my $model = <INFILE> or die "Bad file format";
If you're interested, here's how I'd write this. Notice, I've got rid of the hard-coded file name. Instead, I read from the generic filehandle, <>. This is automatically connected to the file whose name is passed to the program on the command line. This has the advantage that the code is a) easier to write (as you don't need to explicitly open a file) and b) more flexible (as you can process a file with any name). I've also removed a few unnecessary uses of $_ =~.
#!/usr/bin/perl
# Always use these
use strict;
use warnings;
use feature 'say'; # for 'say()'
while (<>) {
s/^\s+//; # No need for $_ =~
s/\s+$//;
if (/work/) {
my $model = <> or die "Bad file format";
if ($model =~ /^good/) {
say 'found good word';
} else {
say 'no good word';
}
}
}

Answer 2

Try this.
Read file into array. Process line by line. You can the check the current and next line.
my $file = 'testFile.txt';
open my $fh, "<", "test_input.txt" or die "can't open the file";
chomp(my #data = <$fh>);
close $fh;
for my $index (0..$#data) {
if($data[$index] =~ /work/){
my $nextIndex = $index + 1;
die "Bad file format" unless(defined $data[$nextIndex]);
print "line below search: $data[$nextIndex]\n";
if ($data[$nextIndex] =~/^good/){
print "found good word\n";
}
else{
print "no good word\n";
}
}
}