SAS-To identify consecutive observations - date

Question

I attempt to identify events occurred in at latest four consecutive years. Assuming I have the following sample.
Rungroup Year
1 2003
1 2004
1 2005
1 2006
1 2008
1 2009
2 2003
2 2004
2 2005
2 2007
2 2008
2 2009
3 2003
3 2004
Based on following code, I want to remove the years that are not consecutive for at least four years. This method has two step. The first step is to give serial number to the consecutive years. The second step is based on look ahead method.
data have;
set have;
by rungroup;
lyear=lag(year);
if first.rungroup then lyear=.;
if year =1+ lyear then group1+1;
else group1=0;
run;
data have3;
set have2;
by rungroup;
set have2 ( firstobs = 2 keep = group1 rename = (group1 = next2) )
have2 ( obs = 1 );
next2 = ifn( last.rungroup, (.), next2 );
set have2 ( firstobs = 3 keep = group1 rename = (group1 = next3) )
have2 ( obs = 2 );
next3 = ifn( last.rungroup, (.), next3 );
set have2 ( firstobs = 4 keep = group1 rename = (group1 = next4) )
have2 ( obs = 3 );
next4 = ifn( last.rungroup, (.), next4);
if next4>=3 or next3>=3 or next2>=3 or group1>=3 then output;
run;
Is this an efficient want way to identify consecutive observations? Any comments would be greatly appreciated.

Answer 1

If your goal is to flag all the obs part of a consecutive sequence of at least 4 years within the same group, here is an approach
data have;
input Rungroup Year;
datalines;
1 2003
1 2004
1 2005
1 2006
1 2008
1 2009
2 2003
2 2004
2 2005
2 2007
2 2008
2 2009
3 2003
3 2004
;
data want(drop=y);
if _N_=1 then do;
declare hash h(dataset:'have');
h.definekey('Rungroup', 'Year');
h.definedone();
end;
set have;
array _{-3:3} _temporary_;
do y=-3 to 3;
_[y]=h.check(key:Rungroup, key:Year+y);
end;
if _[-3]=0 & _[-2]=0 & _[-1]=0
| _[-2]=0 & _[-1]=0 & _[ 1]=0
| _[-1]=0 & _[ 1]=0 & _[ 2]=0
| _[ 1]=0 & _[ 2]=0 & _[ 3]=0
then flag=1;
run;