Using scale-color in netlogo - netlogo

Question

I am using scale-color color number range1 range2
But I am not clear about range1 and range2. What do actually they mean? and how to determine the value for range1 and range2 ?

Answer 1

I believe those are the lower and upper limits of the numbers you might want converted into colors. The number preceding those should be in that range! A number lower than that range will be set to the darkest share (black) , and a number higher than that range will be displayed as the lightest shade ( white ).
You can just open a new model and type some commands into the command line and see what you get. Here's some to try:
ask patches [ set pcolor scale-color red 25 0 50]
ask patches [ set pcolor scale-color red 25 20 50]
ask patches [ set pcolor scale-color red 25 0 30]
ask patches [ set pcolor scale-color red 400 0 30]
ask patches [ set pcolor scale-color red 0 25 30]
Your comment asks how scale-color is used in the climate-change model which has the following code:
to setup-world
set sky-top max-pycor - 5
set earth-top 0
ask patches [ ;; set colors for the different sections of the world
if pycor > sky-top [ ;; space
set pcolor scale-color white pycor 22 15
]
if pycor <= sky-top and pycor > earth-top [ ;; sky
set pcolor scale-color blue pycor -20 20
]
if pycor < earth-top
[ set pcolor red + 3 ] ;; earth
if pycor = earth-top ;; earth surface
[ update-albedo ]
]
end
ok so let's look those statements one at a time.
First:
if pycor > sky-top [ ;; space
set pcolor scale-color white pycor 22 15
]
Looking at the User Dictionary
The template is "scale-color color number range1 range2 "
So range1=22 and range2=15.
The Dictionary says
If range1 is less than range2, then the larger the number, the lighter
the shade of color. But if range2 is less than range1, the color
scaling is inverted.
We have the case where range2 is less than range1, so "the color scaling is inverted", ie the larger the number, the darker the shade of color.
Therefore as pycor increases from 15 to 22 the resulting color will start at white, get darker and darker, and finally become black. That's exactly what we see in the model after hitting setup. As we move upwards above the blue sky, where it transitions to white, outer-space starts at white, gets darker and darker, and finally becomes black.
How about this:
if pycor <= sky-top and pycor > earth-top [ ;; sky
set pcolor scale-color blue pycor -20 20
The model viewport has max-pycor set to 22, so sky-top defined as ( max-pycor - 5 ) would be 17. In other words this is going to look up colors for pycor ranging from 1 to 17.
In this case range1 is less than range2, so if pycor increased from -20 to 20, the resulting color would start at pycor = -20 with black, increase through darker shades till at pycor=0 we have pure blue, and then lighter tints of blue, and end up when pycor=20 at white.
That's exactly what we see in the model between the top of the earth and the top of the blue sky. Except, in the model, earth-top is at pycor=0, so only the numbers from earth-top + 1 (1) to sky-top (17) are ever looked up, and so the resulting reported colors range from blue up through nearly white.
That's exactly what the sky does as pycor goes up from the earth to the sky-top -- it starts at blue and changes gradually to white.
I hope this helps!