Using unquote_splicing in macros with modified lists - macros

Question

Elixir's unquote_splicing works without issues when directly unquoting passed lists. For example, calling the macro below Test1.wrap([1,2,3]) will correctly return [0,0,0,1,2,3,0,0,0].
defmodule Test1 do
defmacro wrap(nums) do
quote do
[0,0,0, unquote_splicing(nums), 0,0,0]
end
end
end
But if I make any changes to the list and then try calling unquote_splicing, Elixir won't even let me define the macro:
defmodule Test2 do
defmacro double_wrap(nums) do
quote do
doubles = Enum.map(unquote(nums), & &1*2)
[0,0,0, unquote_splicing(doubles), 0,0,0]
end
end
end
This will directly raise a compile error:
warning: variable "doubles" does not exist and is being expanded to "doubles()", please use parentheses to remove the ambiguity or change the variable name
iex:37: Test.double_wrap/1
** (CompileError) iex:37: undefined function doubles/0
(elixir) src/elixir_locals.erl:108: :elixir_locals."-ensure_no_undefined_local/3-lc$^0/1-0-"/2
(elixir) src/elixir_locals.erl:108: anonymous fn/3 in :elixir_locals.ensure_no_undefined_local/3
I have tried a bunch of things so far, such as:
Using nested quotes
Using bind_quoted
Going through Macro and Code docs
but nothing has worked and I can't figure out what I'm doing wrong.

Answer 1

What is returned by a macro, is directly injected in place of the calling code. Kernel.SpecialForms.unquote/1 (as well as unquote_splicing/1) is used to get access to the caller context. That is why your code raises: there is no local variable doubles defined in the caller context.
What you can do, would be to declare doubles outside of the quote block.
defmodule D do
defmacro double_wrap(nums) do
doubles = Enum.map(nums, & &1*2)
quote do
[0,0,0, unquote_splicing(doubles), 0,0,0]
end
end
end
require D
D.double_wrap [1,2,3]
#⇒ [0, 0, 0, 2, 4, 6, 0, 0, 0]
That said, this is happily resolved:
doubles = [1,2,3]
quote do: [0,0,0, unquote_splicing(doubles), 0,0,0]
#⇒ [0, 0, 0, 1, 2, 3, 0, 0, 0]
And this is not, because there is no doubles in the caller context:
quote do
doubles = [1,2,3]
[0,0,0, unquote_splicing(doubles), 0,0,0]
end
#⇒ ☠️ ** (CompileError) iex:7: undefined function doubles/0
The error message says undefined function, because elixir tries a local variable, and if it does not find it in the current context, it attempts to call the function with this name and the arity zero.

Answer 2

There's no need to reach outside the quote block to retrieve the value of doubles when doubles is defined inside the quote block. Variables that are defined inside a quote block automatically have their values embedded in the AST. Therefore, you can use the function List.flatten():
defmodule A do
defmacro double_wrap(nums) do
quote do
doubles = Enum.map(unquote(nums), & &1*2)
List.flatten [0,0,0, doubles, 0,0,0]
end
end
end
In iex:
~/elixir_programs$ iex
Erlang/OTP 20 [erts-9.2] [source] [64-bit] [smp:4:4] [ds:4:4:10] [async-threads:10] [hipe] [kernel-poll:false]
Interactive Elixir (1.8.2) - press Ctrl+C to exit (type h() ENTER for help)
iex(1)> c "a.ex"
[A]
iex(2)> require A
A
iex(3)> A.double_wrap [1, 2, 3]
[0, 0, 0, 2, 4, 6, 0, 0, 0]
iex(4)>