Autohotkey, toggle boolean variable not work properly - boolean

Question

I've written an Autohotkey program to toggle zoom in level of Windows built-in magnifier. It's very simple. When you move your mouse to the top left corner, it zooms in, and it zooms out next time you move to the top left corner. Below is my code. The problem is that it always zooms in. I don't know where is the problem. Can anyone help to take a look?
; Timer to check mouse position
SetTimer, CheckMouse, 300
#Persistent
#SingleInstance force
WinGetPos,,,Xmax,Ymax,ahk_class Progman ; get desktop size
T = 4 ; adjust tolerance value if desired
Xmax := Xmax - T ; allow tolerance to mouse corner activation position
Ymax := Ymax - T
CheckMouse: ; check mouse position
CoordMode, Mouse, Screen
MouseGetPos, MouseX, MouseY
GetKeyState, SState, Shift
GetKeyState, AState, Alt
GetKeyState, CState, Control
zoom_toggle := True
if (MouseY < T and MouseX < T and CState = "U" and AState = "U" and SState = "U")
{
if(zoom_toggle)
{
Send #{+}
zoom_toggle := False
}
else
{
Send #{-}
zoom_toggle := True
}
}
Return

Answer 1

Few things to fix/improve.
I'll start off with the actual problem, and then go over stuff you should/could improve.
So the actual problem, every time you run you timer, you set the zoom_toggle variable to be true. So yeah, not much help trying to do any toggles when the value is reset every time.
Move the definition to be at the top of the script, or due to how forgiving ahk is, you could actually entirely skip declaring the variable. That way when it's first used, it's created with the default value of nothing, which evaluates to false.
And now onto other fixes/improvements.
Location of your #directives.
Good/common practice is defining these types of #directives at the very top of your script.
Usage of WinGetPos to get screen width/height.
You could use the A_ScreenWidth and A_ScreenHeight variables to easily get your screen width and height.
Missing return that should end your auto-execute section.
When you launch the script for the very first time, there is nothing that stops the code execution from falling through all the way to your timer's callback label.
Nothing bad will result of this in your case, but for future reference, you don't want this to happen. Use a return to stop code execution and end the auto-execute section.
Redundant code
There is no need to set CoordMode every time you run the timer. Move this command to be at the top of your script.
In your send command, there is no need to wrap - inside { }. That is only done to escape characters that have special meaning in a send command, and - has none. In special cases you may even encounter unwanted behavior by doing this. More about this in the documentation.
Why are Xmax and Ymax being created? They're doing nothing for us?
Usage of Send instead of SendInput
SendInput is faster and more reliable. Should almost always be used over Send.
You can specify SendMode, Input at the top of your script to turn all Send commands into SendInput. Personally I prefer just writing out SendInput.
Legacy code
Technically nothing wrong with using legacy code, but it's definitely not recommended.
Compatibility with future AHK versions is non-existent as well. Expression syntax is what should always be used nowadays.
Use the function GetKeyState() instead of the legacy command.
Use the non-legacy operators (&&, ||, etc) instead of legacy AND, OR, etc.
Always use := instead of =. Legacy assignment is never used.
Usage of a label is pretty much legacy as well. Should replace with a function, but then I should ensure you understand function scopes as well. If you want, I can.
Here's your revised code:
#Persistent
#SingleInstance, Force
CoordMode, Mouse, Screen ;move this to the top, needs to be executed only once
; Timer to check mouse position
SetTimer, CheckMouse, 1000
T := 4 ; adjust tolerance value if desired
Xmax := A_ScreenWidth - T ; allow tolerance to mouse corner activation position
Ymax := A_ScreenHeight - T
;not sure why we're creating these two variables though, they're doing absolutely nothing for us?
return ;end auto-execute section
CheckMouse: ; check mouse position
MouseGetPos, MouseX, MouseY
SState := GetKeyState("Shift", "P")
AState := GetKeyState("Alt", "P")
CState := GetKeyState("Control", "P")
;returns true/false (1/0)
;true meaning the key is down
if (MouseY < T && MouseX < T && !SState && !AState && !CState)
{
;I skipped definin the zoom_toggle variable so it's created for us
;with the default value of nothing, which evaluates to false
;had to flip around the if statement to account for this as well
if(!zoom_toggle)
{
SendInput, #{+}
zoom_toggle := true
}
else
{
SendInput, #-
zoom_toggle := false
}
}
return ;ends the label
To ends off things, I'd like to say this isn't a very good implementation though. To make it at least usable, change the timer to run slower. I made it 1sec in that revised code.
If you want to make it better, a super simple way I could mention, is make it run code only once while the mouse is in that region. Adding another toggle for whether the mouse has exited that region would do it.
Also if you were to have a second monitor that's on the left of your main monitor in Windows, things would get pretty bad haha.