Am I using n-of function incorrectly in netlogo? - netlogo

Question

I'm creating a code that is supposed to make a certain number of turtles have a status of 1 and the rest have a status of 0, the number is calculated using slider inputs from the interface. I've been trying to make the program use n-of but it turns more than the desired number of turtles into the 1 variety (the turtles are set to status 0 from before).
code below (switch for single is to change to only one turtle and tumble switch is for modelling tumbling and running):
to spawn
ifelse (single = false )
[create-turtles N [
set color black
set xcor 0
set ycor 0
set heading random-float 360
set status 0
if (tumble = true)
[
print (N * p1 / (p1 + p2))
ask n-of (N * p1 / (p1 + p2)) turtles [set status 1 set color red]]
]
]
[create-turtles 1 [
set color black
set xcor 0
set ycor 0
set heading random-float 360
pendown
]]
end

Answer 1

The problem is in your placement of the ask n-of statement. The code is the brackets after create-turtles N is executed for each turtle that is created, so each of the N created turtles is in turn asking n-of ... turtles to set status to 1. You will get many more turned turtles than you want. Moving the if (tumble ... block out of the create-turtles block should lead to its being executed only once, after all N turtles are created.
to spawn
ifelse (single = false ) [
create-turtles N [
set color black
set xcor 0
set ycor 0
set heading random-float 360
set status 0
]
if (tumble = true) [
print (N * p1 / (p1 + p2))
ask n-of (N * p1 / (p1 + p2)) turtles [set status 1 set color red]
]
]
[create-turtles 1 [
set color black
set xcor 0
set ycor 0
set heading random-float 360
pendown
]
]
end