How to debug a dataset response - soap

Question

Hello Progress4GL Developers,
I am trying to consume a Magento SOAP API and am dealing with a dataset as my output.
Here is the example procedure from the WSDL Analayser:
I am expecting my XML response to look something like this:
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:ns1="urn:Magento">
<SOAP-ENV:Body>
<ns1:salesOrderListResponseParam>
<result>
<complexObjectArray>
<increment_id>600000018</increment_id>
<store_id>6</store_id>
</complexObjectArray>
<complextObjectArray>
<increment_id>600000019</increment_id>
<store_id>7</store_id>
</complexObjectArray>
</result>
</ns1:salesOrderListResponseParam>
</SOAP-ENV:Body>
</SOAP-ENV:Envelope>
The current code I have is the following where I am expecting an output in the resultTable temp-table (but nothing is currently being returned).
define variable hs as handle no-undo.
define variable hp as handle no-undo.
DEFINE VARIABLE cUsername AS CHARACTER INIT "USERNAME".
DEFINE VARIABLE cPassword AS CHARACTER INIT "PASSWORDAPIKEY".
DEFINE VARIABLE oSession AS CHARACTER NO-UNDO.
DEFINE VARIABLE iRequest AS LONGCHAR NO-UNDO.
DEFINE TEMP-TABLE complexObjectArray NO-UNDO
NAMESPACE-URI ""
FIELD key AS CHARACTER
FIELD value1 AS CHARACTER
XML-NODE-NAME "value"
FIELD filter_id AS RECID
XML-NODE-TYPE "HIDDEN".
CREATE complexObjectArray.
assign
complexObjectArray.key = "status"
complexObjectArray.value1 = "pending".
DEFINE DATASET filter NAMESPACE-URI ""
FOR complexObjectArray.
DEFINE TEMP-TABLE resultTable NO-UNDO
NAMESPACE-URI "complexObjectArray"
FIELD increment_id AS CHARACTER.
DEFINE DATASET resultData NAMESPACE-URI "salesOrderListResponseParam"
FOR resultTable.
create server hs.
hs:connect( "-WSDL WSDLADDRESSHERE" ).
run PortType set hp on server hs.
run login in hp ( input cUsername, input cPassword, output oSession ).
message oSession . PAUSE 100.
run salesOrderList in hp ( input oSession, input dataset filter, output dataset resultData ).
for each resultTable:
disp resultTable with 2 col.
end.
delete procedure hp.
hs:disconnect().
delete object hs.
There are no errors, but it fails to show a response in the temp-table.
Many Thanks in Advance!

Answer 1

First of all you should try to create a dataset that exactly matches your expected output. I would do it something like this.
I'm unsure about the namespace, ns1. You could try to include it in the XML-NODE-NAME or via the NAMESPACE-PREFIX attribute. But it might work even if you just leave it out.
DEFINE TEMP-TABLE ttResult NO-UNDO
XML-NODE-NAME "result"
FIELD id AS INTEGER SERIALIZE-HIDDEN.
DEFINE TEMP-TABLE ttcomplexObjectArray NO-UNDO
XML-NODE-NAME "complexObjectArray"
FIELD id as RECID SERIALIZE-HIDDEN
FIELD increment_id AS CHARACTER
FIELD store_id AS CHARACTER.
DEFINE DATASET dsSalesOrderListResponseParam XML-NODE-NAME "salesOrderListResponseParam"
FOR ttResult, ttcomplexObjectArray
PARENT-ID-RELATION pr1 FOR ttResult, ttcomplexObjectArray PARENT-ID-FIELD id.
DATASET dsSalesOrderListResponseParam:READ-XML("file", "c:\temp\xml.xml", ? , ? , ?).
This works with the "body" part of your expected response (XML-Envelope etc excluded) as below.
<?xml version="1.0" ?>
<salesOrderListResponseParam >
<result>
<complexObjectArray>
<increment_id>600000018</increment_id>
<store_id>6</store_id>
</complexObjectArray>
<complexObjectArray>
<increment_id>600000019</increment_id>
<store_id>7</store_id>
</complexObjectArray>
</result>
</salesOrderListResponseParam>
Start with saving your response as the dataset sees it:
dsSalesOrderListResponseParam:WRITE-XML("file", "response.xml").
Then you can look at the file and see what's there. That's a start at least!

Answer 2

Thanks #Jensd for your answer. Using the write-xml statement really helps to identify how the dataset is structured.
There were three problems with my code above.
It needed the SERIALIZE-NAME statement in the temp-tables.
The filter was not being created correctly, and by using the write-xml statement I was able to identify what was going wrong.
I needed to assign a filter_id to the complexobjectarray which is equal to the recid of the filter temptable (which basically nests the XML as needed).
Please find below the code which resolved this issue (should it be of use to anybody else trying to do this):
define variable hs as handle no-undo.
define variable hp as handle no-undo.
DEFINE VARIABLE cUsername AS CHARACTER INIT "USER".
DEFINE VARIABLE cPassword AS CHARACTER INIT "PASS".
DEFINE VARIABLE oSession AS CHARACTER NO-UNDO.
DEFINE VARIABLE iRequest AS LONGCHAR NO-UNDO.
/* creating the filter */
DEFINE TEMP-TABLE filter NO-UNDO
FIELD filter_field AS INTEGER
XML-NODE-TYPE "HIDDEN" .
DEFINE TEMP-TABLE complexObjectArray NO-UNDO
SERIALIZE-NAME "complexObjectArray"
FIELD key AS CHARACTER
FIELD value1 AS CHARACTER
XML-NODE-NAME "value"
FIELD filter_id AS RECID
XML-NODE-TYPE "HIDDEN" .
CREATE filter.
CREATE complexObjectArray.
assign
complexObjectArray.key = "status"
complexObjectArray.value1 = "pending"
complexObjectArray.filter_id = RECID(filter).
.
DEFINE DATASET filters
FOR filter, complexObjectArray
PARENT-ID-RELATION RELATION1 FOR filter, complexObjectArray
PARENT-ID-FIELD filter_id.
/* debug dataset filters */
DATASET filters:WRITE-XML("file", "/home/jbetts/request.xml", ? , ? , ?).
DEFINE TEMP-TABLE resultTable NO-UNDO
SERIALIZE-NAME "complexObjectArray"
FIELD increment_id AS CHARACTER.
DEFINE DATASET resultData SERIALIZE-NAME "salesOrderListResponseParam"
FOR resultTable.
create server hs.
hs:connect( "-WSDL WSDLHERE" ).
run PortType set hp on server hs.
run login in hp ( input cUsername, input cPassword, output oSession ).
message oSession . PAUSE 100.
run salesOrderList in hp ( input oSession, input dataset filters, output dataset resultData ).
for each resultTable:
disp resultTable.increment_id format "x(30)".
end.
find first resultTable no-lock no-error.
if not available resulttable then message "no results".
delete procedure hp.
hs:disconnect().
delete object hs.