Merge two dataframes by date in SAS - merge

Question

I have two tables and I want to merge them by id and by the latest date before the date in df1 for the relevant id.
data df1;
input id $ date value ;
informat date yymmdd10.;
format date yymmdd10. ;
cards;
a 19991231 1
a 20011231 2
b 20151231 4
;
data df2;
input id $ date ;
informat date yymmdd10.;
format date yymmdd10.;
cards;
a 20020101
c 20160701
;
I tried this, but there's something missing.
proc sql;
create table output
as select a.*, b.date
from df1 as a, df2 as b
where a.id = b.id
group by a.id, b.id
having (a.date) > max(b.date);
quit;
Desired output:
data output;
input id $ date value;
informat date yymmdd10.;
format date yymmdd10.;
cards;
a 20011231 2
;

Answer 1

I'd do it in two steps, with a PROC SQL to join and sort the two tables, then a data step to only output the latest date for each ID.
proc sql;
create table o1 as
select a.id,
a.date,
a.value
from df1 a
join df2 b
on b.id = a.id
and b.date > a.date
order by a.id, a.date
;
quit;
data output;
set o1;
by id;
if last.id then output;
run;

Answer 2

You can use SET to interleave the records. Use RETAIN to keep the last version of VALUE from the first dataset. You didn't indicate whether you have any missing values of VALUE, but let's test for that anyway.
data want;
set df1(in=in1) df2(in=in2);
by id date ;
retain last_value;
if first.id then last_value=.;
if in1 and not missing(value) then last_value=value;
if in2 and not missing(last_value);
run;
Result:
last_
Obs id date value value
1 a 2002-01-01 . 2
Note this method takes the value on or before the DATE in the second dataset. If you want it only take the last value BEFORE that date then reverse the order that the two datasets are referenced in the SET statement.

Answer 3

proc sort data=df1;
by id descending date;
proc sort data=df2;
by id;
data want;
merge df1 (in=in1) df2 (in=in2 rename=(date=date_max));
by id;
** Assume you want only values that are in both datasets **;
if in1 & in2;
retain flag;
if first.id then flag = 0;
** If no dates before max date yet and this one is before max date, we have a winner **;
if flag = 0 & date < date_max then do;
** Set flag to indicate this ID has already found the max date **;
flag = 1;
output;
end;
run;