Join two matches in Neo4J - group-by

Question

Im new in neo4j and I need help I have the following problem:
I have a little database that describes the reviews of a movie.
Basically, the nodes are set like this:
(Critic)-[review]->(Movie)
The review relation has an attribute called stars which describe the stars given by the critic to the movie.
An example is this.
(Jon)-[review{stars:4}]->(Titanic)
(Jon)-[review{stars:3}]->(Avatar)
(Alf)-[review{stars:4}]->(Avatar)
I have an excersice that Ive been asked to get all the critics name that have given 4 star in their reviews but never gave an 3.
The answer in this case must be Alf
First I have a match for the critic that gave 4 stars (Jon,Alf) and then I get a match for the critics that gave 3 (Jon). Now I want to inner join them to only get Alf. How I can do this? This is what ive got so far:
MATCH (N:Critic)-[r:REVIEWS]->()
WHERE r.Stars=4 with distinct n.Name as names4
MATCH (m:Critic)-[s:REVIEWS]->()
WHERE s.Stars=3 with distinct m.Name as names3, names4 as names4
RETURN distinct [n IN names4 WHERE NOT n IN names3 ] as listC
As you se I have the two matches but I dont know how to make the inner join

Answer 1

You can simplify your query a lot. Cypher is quite cool and expressive :)
MATCH (c:Critic)
WHERE (c)-[:REVIEWS{Stars:4}]->() AND
NOT (c)-[:REVIEWS{Stars:3}]->()
RETURN c.name as critic_name
The way you have tried would also work, you have to change the query to:
// Get all the critics who given a score 3
MATCH (c:Critic)-[r:REVIEWS]->()
WHERE r.Score = 3
WITH collect(distinct c) as score_3_critics
// get all critics who gave a score 4, but filter out
// critics who gave it 3
MATCH (c1:Critic)-[r1:REVIEWS]->()
WHERE r1.Score = 4 AND NOT c1 in score_3_critics
RETURN distinct c1.name as critic
I always preferred filtering out results as in the first example. When you have multiple ways of defining a query to get the same results, it is best to check the execution plan with the PROFILE statement to see which query is faster