ActionScript3 How to increment score when working with classes - class

Question

I would like to increment the value of a TextField by one every time an event listener in another class is activated. This is proving very difficult because the event listener can only be triggered once the Timer in the main class reaches completion.
I have tried using a getter method on a Boolean to ensure that the event listener in a different class has been triggered. This has proven unsucsessful however because of the Timer which is only triggered once on completion.
I am a begginer to AS3 and so any help would be greately appreciated. Thank You
THIS IS THE CODE FOR THE MAIN CLASS
public function t1Finish(e:TimerEvent):void {
ranNum2 = randomNum1(0, 11);
holes[ranNum2].sendUp();
setCounter();
}
public function setCounter():void {
if(holes[ranNum2].returnHasHit() == true) {
counter1++;
txt1instance.text = counter1.toString();
} else {
txt1instance.text = counter1.toString();
}
}
THIS IS THE CODE FOR THE OTHER CLASS
public function click1(e:MouseEvent):void {
this.gotoAndPlay(32);
hasHit = true;
}
public function returnHasHit():Boolean {
return hasHit;
}

Answer 1

You need to properly arrange your app hierarchy. Your case is not exactly problematic: you have main class that wants to capture some events occurring in certain subservient objects.
// That HOLE class.
// I assume it is an inner event handler, not a public
// interface, thus there's no need for it to be public.
private function click1(e:MouseEvent):void
{
// Normally you don't need to explicitly state "this".
gotoAndPlay(32);
// Produce a custom event.
dispatchEvent(new Event(Event.OPEN));
}
Then, you need to catch that event in the main class.
// The MAIN class.
// You need to subscribe for that custom event somewhere.
private function subscribeAll():void
{
for each (var aHole:MovieClip in holes)
{
aHole.addEventListener(Event.OPEN, onOpen);
}
}
// The custom event handler.
private function onOpen(e:Event):void
{
// If you want to know which hole dispatched this event.
var aHole:MovieClip = e.target as MovieClip;
// Here you might want to put any additional criteria
// to check if you want to accept this event.
// This handler is invoked ONLY if that "click1" handler was invoked
// on any of the holes, so there's no need to check "wasHit" interface.
counter1++;
txt1instance.text = counter1.toString();
}