How to set up kdb RDB to only subscribe to certain tables in tickerplant - kdb

Question

I want to set up 2 RDB instances using the same script where one instance subscribes to 2 tables and the other instance subscribes to a separate table in the tickerplant. I am trying to manipulate .u.sub but with no success
if[system"p"=RDB_INSTANCE_1;
.u.rep .(hopen `$":",.u.x 0)"({.u.sub[x;`]} each `trade`quote;`.u `i`L)";
];
if[system"p"=RDB_INSTANCE_2;
.u.rep .(hopen `$":",.u.x 0)"(.u.sub[`aggTradeStats;`];`.u `i`L)";
];
or
?[system"p"=RDB_INSTANCE_1;..u.rep .(hopen `$":",.u.x 0)"({.u.sub[x;`]} each `trade`quote;`.u `i`L)"; .u.rep .(hopen `$":",.u.x 0)"(.u.sub[`aggTradeStats;`];`.u `i`L)"];
Any idea how I can achieve this?

Answer 1

The vanilla tick scripts aren't that flexible when it comes to subscription options, but without going too far down the rabbit hole, the few quick changes below should allow you to do what you asked (I haven't tested the below further than initiating the instances)
.u.sub changes to the below to allow subscription to all tables (`), a list of tables or single table
{$[x~`;.z.s[;y]each t;1<count x;.z.s[;y]each x;[if[not x in t;'x];del[x].z.w;add[x;y]]]};
r.q changes to the below where the required tables are passed in via a command line flag. I've removed references to .z.x and parsed the various flags. The last line builds out the list of tables in string format (not very elegant but it's a quick solution).
/q tick/r.q [host]:port[:usr:pwd] [host]:port[:usr:pwd]
/2008.09.09 .k ->.q
if[not "w"=first string .z.o;system "sleep 1"];
upd:insert;
args:.Q.opt .z.x;
/ get the ticker plant and history ports, defaults are 5010,5012
/.u.x:.z.x[0],(count .z.x 0)_(":5010";":5012");
/ end of day: save, clear, hdb reload
.u.end:{t:tables`.;t#:where `g=attr each t#\:`sym;.Q.hdpf[`$"::",first args`hdb;`:.;x;`sym];#[;`sym;`g#] each t;};
/ init schema and sync up from log file;cd to hdb(so client save can run)
.u.rep:{if[0>type first x;x:enlist x];(.[;();:;].)each x;if[null first y;:()];-11!y;system "cd ",1_-10_string first reverse y};
/ HARDCODE \cd if other than logdir/db
/ connect to ticker plant for (schema;(logcount;log))
.u.rep .(hopen `$"::",first args`tp)"(.u.sub[`",("`" sv args`tabs),";`];`.u `i`L)";
Then start up RDBs as follows
ec2-user#/home/ec2-user $ ## RDB 1 table
ec2-user#/home/ec2-user $ q tick/r.q -tp 5010 -hdb 6000 -tabs trade -q
tables[]
,`trade
ec2-user#/home/ec2-user $ # RDB 2 tables
ec2-user#/home/ec2-user $ q tick/r.q -tp 5010 -hdb 6000 -tabs trade quote -q
tables[]
`quote`trade
ec2-user#/home/ec2-user $ ## RDB all tables
ec2-user#/home/ec2-user $ q tick/r.q -tp 5010 -hdb 6000 -q
tables[]
`s#`other`quote`trade
Check subscription dict back on tp
q).u.w
other| ,(9i;`)
quote| ((8i;`);(9i;`))
trade| ((7i;`);(8i;`);(9i;`))
Hope this helps, as I said, I haven't tested beyond this point
Jason