Change the Order of the Footnotes - ms-word

Question

I would like to change the footnote in the text. More specifically I want to put the full stop after the footnote like in this concept.
Online seems the only solution is with a macro, but I have no idea where to start.
I've only found this script close to the solution
Sub UpdateFootnotes()
'Update fields in all footnotes.
Dim doc As Document
Dim rng As Range
Set doc = ActiveDocument
If doc.Footnotes.Count <> 0 Then
'Select all footnotes.
Set rng = doc.Footnotes(1).Range
rng.WholeStory
rng.Select
'Update all fields.
Selection.Fields.Update
End If
End Sub
I need to do it for my bachelor thesis, it would really help me a lot!
Edit: from a posted answer in Microsoft forums here

Answer 1

The macro you found has nothing to do with changing the position of footnote references; it simply updates any fields in footnotes.
The following macro processes footnotes and endnotes.
Sub FootnoteEndnoteFix()
Application.ScreenUpdating = False
Dim FtNt As Footnote, EndNt As Endnote, Rng As Range
With ActiveDocument
For Each FtNt In .Footnotes
Set Rng = FtNt.Reference
With Rng
'Eliminate any spaces before the footnote
While .Characters.First.Previous.Text = " "
.Characters.First.Previous.Text = vbNullString
Wend
'Swap the footnote/punctuation, as applicable
Select Case .Characters.First.Previous
Case ".", ",", "!", "?", ":", ";"
.InsertAfter .Characters.First.Previous
.Characters.First.Previous.Text = vbNullString
.Characters.Last.Font.Superscript = False
End Select
End With
Next
For Each EndNt In .Endnotes
Set Rng = EndNt.Reference
With Rng
'Eliminate any spaces before the endnote
While .Characters.First.Previous.Text = " "
.Characters.First.Previous.Text = vbNullString
Wend
'Swap the endnote/punctuation, as applicable
Select Case .Characters.First.Previous
Case ".", ",", "!", "?", ":", ";"
.InsertAfter .Characters.First.Previous
.Characters.First.Previous.Text = vbNullString
.Characters.Last.Font.Superscript = False
End Select
End With
Next
End With
Application.ScreenUpdating = True
End Sub