Completion for filenames without root, only extension (hidden files) - fish

Question

I'm trying to write a completion for a command that takes filenames that have no root/base part, only extension (such as "foo/.ext"). Hidden files. (Specifically, ".envrc" for direnv.)
There are several examples to follow in fish's installation that use
__fish_complete_suffix for files that have a root and extension, such as fish itself:
complete -c fish -k -x -a "(__fish_complete_suffix .fish)"
The same thing for hidden files, files without a root, doesn't work.
# completions/foo.fish
complete -c foo -k -x -a "(__fish_complete_suffix .bar)"
# functions/foo.fish
function foo
echo $argv
end
> mkdir -p a/b; touch a/1.bar a/2.bar a/.bar
> foo a/<TAB>
a/1.bar a/2.bar a/b/
Is there a way to accomplish this with this or some other function(s)?

Answer 1

fish doesn't add hidden files to the list of completions unless the token being completed already starts with a '.'.
You should be able to write a custom completion that does what you want, but unfortunately a long-standing bug makes that impossible.

Answer 2

I spent way too much time on this, it may be overly complex, and probably needs to be optimized and simplified, but it does work in almost every case. The one case that doesn't is the outstanding bug #Zanchey mentioned.
# completions/foo.fish
complete -c foo -k -x -a "(__fish_complete_dotfile_or_subdirectories .bar)"
function __fish_complete_dotfile_or_subdirectories -d "Complete dotfile or directories"
set -l token
set -l suffix
switch (count $argv)
case 1
set token (commandline -ct)
set suffix $argv
case 2
set token $argv[1]
set suffix $argv[2]
end
set -l suffix_len (string length $suffix)
# trim leading . from suffix if present
if test (string sub -l 1 $suffix) = "."
set suffix_len (math $suffix_len - 1)
set suffix (string sub -l $suffix_len -s "-"$suffix_len $suffix)
end
set -l root_name (string split -rm 1 "/" $token)
set -l root $root_name[1..-2]"/"
set -l name $root_name[-1]
# build regex
# $suffix = foo -> '^(?:|\.|\.f|\.fo|\.foo)$'
# $suffix = bar -> '^(?:|\.|\.b|\.ba|\.bar)$'
set -l re (
echo -n "^(?:|\."
for i in (seq $suffix_len)
echo -n "|\."(string sub -l $i $suffix)
end
echo ')$'
)
if string match -qr $re "$name"
set -l i
if test -n "$root"
set i (printf "%s.%s" $root $suffix)
else
set i (printf ".%s" $suffix)
end
if test -f "$i"
printf "%s\n" $i
end
end
# all subdirs except . and ..
for i in (complete -C "nonexistentcommand $token" |
string match -er '[^\.]/$')
printf "%s\n" $i
end
end
* (complete -C ... line inspiration)
> mkdir -p a/{.a1,.a2,b1,b2,.b3,.b4} c
> touch .bar .baz a/.bar a/.baz a/foo.bar c/.bar
> tree -aF
.
├── a/
│   ├── .a1/
│   ├── .a2/
│   ├── b1/
│   ├── b2/
│   ├── .b3/
│   ├── .b4/
│   ├── .bar
│   ├── .baz
│   └── foo.bar
├── .bar
├── .baz
└── c/
└── .bar
> foo <TAB>
> __fish_complete_dotfile_or_subdirectories "" bar
.bar # .bar is included ...
a/
c/
> foo <TAB>
a/ c/ # ... but is not here because of the long-standing bug
> foo .<TAB> # completes to `foo .bar`
> foo ./<TAB>
./.bar ./a/ ./c/ # now it's included
> foo ./.<TAB> # completes to `foo ./.bar`
> foo a<TAB> # completes to `foo a/`
> foo a/<TAB>
a/.bar a/b1/ a/b2/
> foo a/.<TAB>
a/.bar a/.a1/ a/.a2/ a/.b3/ a/.b4/
> foo a/.b<TAB>
a/.bar a/.b3/ a/.b4/
> foo a/.ba<TAB> # completes to `foo a/.bar`
> foo c<TAB> # completes to `foo c/`
> foo c/<TAB> # completes to `foo c/.bar`