how to print space contain attribute in Perl Script - perl

Question

I have some data in input file
user date="" name="" id="small"
user date="" name="" id="sample test"
user date="" name="" id="big city"
I want to get only id's from above file
code::-
use strict;
use warnings;
my $input = "location\input.txt";
open("FH","<$input") or die;
while(my $str = <FH>)
{
my #arr = split(/ /,$str);
$arr[2] =~ s/id=//g;
$arr[2] =~ s/"//g;
print "$arr[2]\n";
}
close("FH");
Output :
small
sample
big
Note :: Here I'm not able to print complete word like "small test", "big city"
Expectation : I need to get complete word "sample test" and "big city" anyone please help me on this

Answer 1

If you know the format will always have quotes after id, you can do:
use feature qw(say);
use strict;
use warnings;
open my $fh, "<", "location/input.txt" or die $!;
while (my $line = <$fh>) {
my ($id) = $line =~ /id="(.*?)"/;
say $id;
}
Breaking down that complicated line we have:
$line =~ /id="(.*?)"/: match id="..." and grab the smallest possible
.... If you use .* instead, you will grab up until the last " of the line, which might belong to another field. This is not the case for id, but try it with date and you'll see.
my ($id) = ...: process the regex match in list context, which returns the capture groups, and assign it pairwise to the list ($id). Concretely, this stuffs the matched value in $id
say $id: prints $id with an automatic newline after it.

Answer 2

A nice module for handling quoted strings is Text::ParseWords. It is a core module too, making it even handier. You can use it here to easily split the string on whitespace, then parse the result into hash keys.
use strict;
use warnings;
use Data::Dumper;
use Text::ParseWords;
while (<DATA>) {
chomp;
my %data = map { my ($key, $data) = split /=/, $_, 2; ($key => $data); } quotewords('\s+', 0, $_);
print Dumper \%data;
}
__DATA__
user date="" name="" id="small"
user date="" name="" id="sample test"
user date="" name="" id="big city"
Output:
$VAR1 = {
'user' => undef,
'name' => '',
'date' => '',
'id' => 'small'
};
$VAR1 = {
'name' => '',
'date' => '',
'id' => 'sample test',
'user' => undef
};
$VAR1 = {
'id' => 'big city',
'date' => '',
'name' => '',
'user' => undef
};

Answer 3

A simplified version to extract data of interest
use strict;
use warnings;
use feature 'say';
use Data::Dumper;
while(<DATA>) {
my %d = /(\w+)="(.*?)"/g;
say 'id: ' . $d{id};
say Dumper(\%d);
}
__DATA__
user date="" name="" id="small"
user date="" name="" id="sample test"
user date="" name="" id="big city"
Output
id: small
$VAR1 = {
'date' => '',
'id' => 'small',
'name' => ''
};
id: sample test
$VAR1 = {
'id' => 'sample test',
'date' => '',
'name' => ''
};
id: big city
$VAR1 = {
'name' => '',
'id' => 'big city',
'date' => ''
};