Prevent user from Enter-pressing on MESSAGE type I? - popup

Question

Is there any way to disable the enter key when a MESSAGE TYPE I is displayed? The users are just pressing away the note without reading it.
We want to force them to actually click the green button to confirm the message instead (Yes, I know it's dumb, but I was tasked to implement this so wcyd).
SELECT SINGLE text
FROM ZWM_MATVERMERK
INTO lv_verm
WHERE matnr = <lf_main>-matnr
AND werk = <lf_main>-werks.
IF lv_verm IS NOT INITIAL.
MESSAGE | Note: { lv_verm } | TYPE 'I'.
CLEAR lv_verm.
ENDIF.

Answer 1

You can use the function module POPUP_TO_CONFIRM to create a modal dialog which gives you more control than the standard MESSAGE TYPE 'I'.
Among others, this function module has the parameter default_button which decides which button is the one highlighted when the popup appears and thus will be considered clicked when the user just presses enter.
DATA lv_answer TYPE c.
CALL FUNCTION 'POPUP_TO_CONFIRM'
EXPORTING
text_question = 'Are you sure?'
default_button = 2
IMPORTING
answer = lv_answer.
" lv_answer will be '1' for yes, '2' for no and 'A' for canceling the dialog.
If you want to make really really sure that the user read the message, then one option is to use POPUP_TO_GET_ONE_VALUE to make the user confirm that they read the message by reciting something from it.
DATA lv_answer TYPE c.
DATA lv_value TYPE pvarfield.
CALL FUNCTION 'POPUP_TO_GET_ONE_VALUE'
EXPORTING
titel = 'Safety check'
textline1 = |This operation will affect { lv_count } items.|
textline2 = |When you are aware of that, please enter "{ lv_count }" below:|
valuelength = 20
IMPORTING
answer = lv_answer
value1 = lv_value.
IF lv_answer = 'J' and lv_value = lv_count.
"...proceed...
ENDIF.
This will look like this:
By the way: There are a lot more standard function modules starting with POPUP_* which cover a wide variety of common use-cases for modal dialogs. Some of those can be really useful.