We have a bunch of .bat build scripts which are invoked by a PowerShell based GitLab runner that were recently refactored from:
program args
if !errorlevel! neq 0 exit /b !errorlevel!
to the more succinct:
program args || exit /b
Today I investigated a build job which obviously failed if you looked at the error log but which was reported as a success. After much experimentation I discovered that this pattern didn't always work as expected:
program args || exit /b
but this did appear to work when the former didn't:
program args || exit /b !errorlevel!
I've read the SO question Windows batch exit option b with or without errorlevel and the statement below from https://www.robvanderwoude.com/exit.php but still can't quite explain what I'm observing.
The DOS online help (HELP EXIT) doesn't make it clear that the /B parameter exits the current instance of script which is not necessarily the same as exiting the current script.
I.e. if the script is in a CALLed piece of code, the EXIT /B exits the CALL, not the script.
This is the minimal batch file I used to explore this:
#echo off
setlocal EnableDelayedExpansion
cmd /c "exit 99" || exit /b
:: cmd /c "exit 99" || exit /b !errorlevel!
And this is how I invoked the batch file (to simulate how it was invoked by the GitLab PowerShell based runner):
& .\test.bat; $LastExitCode
Here is the output depending on which of the two lines in the batch file is executed:
PS> & .\test.bat; $LastExitCode
0
PS> & .\test.bat; $LastExitCode
99
There is another way to get the correct behaviour which is to invoke the batch file longhand from within PowerShell using CALL as well:
PS> & cmd.exe /c "call .\test.bat"; $LastExitCode
99
While I appreciate that this may be the correct way to invoke a batch file from PowerShell, that does not appear to be common knowledge based on the many examples I've seen. Also I wonder why PowerShell doesn't invoke a batch file this way if it's "the right way". Lastly I still don't understand why, when leaving off the call, the behaviour changes depending on whether we add the !errorlevel! to the exit /b statement.
UPDATE: Thanks for all the discussion so far but I feel it's getting lost in the weeds which is probably my fault for being too vague in my original question. What I think I'm really after (if possible) is a definitive statement about when the errorlevel is (supposedly) evaluated in the following statement:
program || exit /b
Is it really evaluated early (i.e. before program is run) like this:
program || exit /b %errorlevel%
Or is it evaluated lazily (i.e. when exit is being executed after program has run and internally errorlevel has been updated), more analogous to this:
program || exit /b !errorlevel!
Hence I'm not really after speculation unless, sadly, that is the best that we can do in which case knowing there is no definitive answer or that it's a bug is an acceptable answer to me :o).
Workarounds:
Call your batch file via cmd /c "<batch-file> ... & exit", in which case the || exit /b solution without an explicit exit code works as expected:
cmd /c ".\test.bat & exit"
If needed, escape any embedded " characters as `", such as around batch-file paths and pass-through arguments that contain spaces: cmd /c ".\test.bat `"quoted argument`" & exit"
Alternatively, if you don't need PowerShell's string interpolation to embed variable values in the call, you can use '...' quoting, in which case embedded " can be used as-is: cmd /c '.\test.bat "quoted argument" & exit'
Using cmd /c "<batch-file> ... & exit" routinely to call batch files from outside cmd.exe is advisable, as even batch files without explicit exit /b (or exit) calls can otherwise behave unexpectedly - see this answer.
Alternatively - but only if your batch file never needs to be called from another batch file to which control should be returned and if it never needs to be part of a cmd /c multi-command command line where it isn't the last command[1] - you can use || exit instead of || exit /b - this exits the executing cmd.exe process as a whole, instantly, but the exit code (error level) is then reliably reported (at least in the context of a <command> || exit statement) also with direct invocation from outside cmd.exe, such as & .\test.bat (or, in this simple case, just .\test.bat) from PowerShell.
While combining setlocal EnableDelayedExpansion with exit /b !ERRORLEVEL! works too (except inside (...) - see this post) - due to using an explicit exit code - it is obviously more cumbersome and can have side effects, notably quietly removing ! characters from commands such as echo hi! (while it's possible to minimize that problem by placing the setlocal EnableDelayedExpansion call on the line just before an exit /b call, that would require duplication if there are multiple exit points).
cmd.exe's behavior is unfortunate in this case, but can't be avoided.
When calling a batch file from outside cmd.exe:
exit /b - without an exit-code (error-level) argument - only sets the cmd.exe process exit code as expected - namely to the exit code of the most recently executed command in the batch file - if you follow the batch-file call with & exit, i.e. as cmd /c <batch-file> ... `& exit
Without the & exit workaround, an argument-less exit /b call from a batch file is reflected in the %ERRORLEVEL% variable intra-cmd.exe-session, but that doesn't translate to cmd.exe's process exit code, which then defaults to 0.[1]
With the & exit workaround, intra-batch-file argument-less exit /b does properly set cmd.exe's exit code, even in a <command> || exit /b statement, in which case <command>'s exit code is relayed, as intended.
exit /b <code>, i.e. passing an exit code <code> explicitly, always works[2], i.e. the & exit workaround is then not needed.
This distinction is an obscure inconsistency that could justifiably be called a bug; Jeb's helpful answer has sample code that demonstrates the behavior (using the less comprehensive cmd /c call ... workaround as of this writing, but it applies equally to cmd /c "... & exit").
[1] With cmd /c, you can pass multiple statements for execution, and it is the last statement that determines the cmd.exe process' exit code. E.g, cmd /c "ver & dir nosuch" reports exit code 1, because the non-existent file-system item nosuch caused dir to set the error level to 1, irrespective of whether or not the preceding command (ver) succeeded. The inconsistency is that, for a batch file named test.bat which exits with exit /b without an explicit exit-code argument, cmd /c test.bat always reports 0, whereas cmd /c test.bat `& exit properly reports the exit code of the last statement executed before the batch file exited.
[2] The exit code may be specified literally or via a variable, but the pitfall is that - due to cmd.exe's up-front variable expansion - <command> || exit /b %ERRORLEVEL% does not work as intended, because %ERRORLEVEL% at that point expands to the error level prior to this statement, not to the one set by <command>; this is why delayed expansion, via having run setlocal enabledelayedexpansion or having invoked the cmd.exe with the /V option, is necessary in this case: <command> || exit /b !ERRORLEVEL!
There is a difference between exit /b and exit /b <code>.
As mklement0 states, the difference becomes visible when calling a batch file with or without CALL
In my tests, I used (call) to force the errorlevel to 1.
test1.bat
#echo off
(call)
exit /b
test2.bat
#echo off
(call)
exit /b %errorlevel%
Testing with test-all.bat:
cmd /c "test1.bat" & call echo Test1 %%errorlevel%%
cmd /c "call test1.bat" & call echo call Test1 %%errorlevel%%
cmd /c "test2.bat" & call echo Test2 %%errorlevel%%
cmd /c "call test2.bat" & call echo call Test2 %%errorlevel%%
Output:
Test1 0
call Test1 1
Test2 1
call Test2 1
To get an always reliable errorlevel, you should use the explicit form of exit /b <code>.
In case of using the construct <command> || exit /b !errorlevel! the delayed expansion is necessary or the form
<command> || call exit /b %%errorlevel%%
Another solution
<command> || call :exit
...
:exit
(
(goto) 2>nul
exit /b
)
This uses the batch exception handling
Does Windows batch support exception handling?
Let's look at the three possible scenarios:
cmd /c "exit 99" || exit /b
returns 0 because cmd /c "exit 99" executed correctly
cmd /c "exit 99" || exit /b !errorlevel!
returns 99 because cmd /c "exit 99" set errorlevel to 99 and we are returning the errorlevel which results from executing cmd /c "exit 99"
cmd /c "exit 99" || exit /b %errorlevel%
returns ? - errorlevel as it was when the cmd /c "exit 99" line was parsed as it was
at that time that `%errorlevel% was evaluated.
If delayedexpansion was not set, then the only difference is that the !errorlevel! scenario attempts to assign a string to the error level, which most probably won't work very well.
As for Powershell - it's a corner case on a road less travelled. A scenario that was not tested thoroughly as the designers expected to execute .exes, etc. using this facility. No doubt even if it is reported, it would not be fixed as there's a workaround, even if it's not well-exposed.
This is, I believe, the fail-to-fail scenario - a facility that's assumed to work because the right conditions to cause it to fail are rarely met.
In the same way,
echo %%%%b
is ambiguous. Does it mean to echo the literal %%b or to echo % prefixed to the contents of metavariable b? (Answer : the latter). Not exactly encountered every day. What chance that the ambiguity will be resolved - ever? We can't even get /u implemented on the date command to have it deliver the date in a universal format which would solve the vast majority of date-oriented questions posted on the batch tag. As for the possibility of a switch to allow date to deliver days-since-some-epoch-date - I haven't even bothered to suggest it since, despite inviting suggestions for cmd modifications, absolutely nothing has been done about facilities offered, just user-interface changes. Off playing with all the shiny things while ol' faithful languishes in the bottom of a locked filing cabinet stuck in a disused lavatory with a sign on the door saying ‘Beware of the Leopard.”
Eliminating the irrelevant PowerShell and Cmd.exe invocation complexities so we can see how the cmd interpreter works:
#setlocal EnableExtensions EnableDelayedExpansion
#set prompt=$G
call :DefaultExit
#echo %ErrorLevel%
call :ExplicitExit
#echo %ErrorLevel%
#rem ErrorLevel is now 2
call :DefaultExit || echo One-liner ErrorLevel==%ErrorLevel%, not zero!
#echo %ErrorLevel%
#rem Reset the errorlevel to zero
call :DefaultExit
#echo %ErrorLevel%
call :ExplicitExit || echo One-liner ErrorLevel==!ErrorLevel!
#echo %ErrorLevel%
#exit /b
:DefaultExit
exit /b
:ExplicitExit
exit /b 2
Yields:
> test
>call :DefaultExit
>exit /b
0
>call :ExplicitExit
>exit /b 2
2
>call :DefaultExit || echo One-liner ErrorLevel==2, not zero!
>exit /b
One-liner ErrorLevel==2, not zero
2
>call :DefaultExit
>exit /b
2
>call :ExplicitExit || echo One-liner ErrorLevel==!ErrorLevel!
>exit /b 2
One-liner ErrorLevel==2
2
As you can see, exit /b is exactly equivalent to exit /b %ErrorLevel%, which is NOT what you want with your || failure execution path. You must invoke delayed expansion to get the results from the left side of the || operator.
I ran one more quick test of the above script and interactively checked the error level from the console window after the script exited:
> echo %errorlevel%
2
As you can see, exit /b alone, returned 2, which was the previously set error level. So my hunch seems correct. You definitely require delayed expansion of some form !ErrorLevel! or %^ErrorLevel% (as per #aschipfl).
The & operator of PowerShell internally invokes cmd.exe /C when running a batch file. I bet $LastExitCode refers to invocation of cmd.exe rather than to the batch file. In this context, call passes over the ErrorLevel from the batch file to cmd.exe.
The same issue arises in cmd.exe (with PowerShell not involved at all), running .\test.bat & call echo %^ErrorLevel% does not invoke cmd.exe /C to run the batch file, so this works (meaning it always returns 99). However, cmd /C .\test.bat & call echo %^ErrorLevel% just fails like your PowerShell attempt (returning 0 with your batch file as it stands), and cmd /C call .\test.bat & call echo %^ErrorLevel% succeeds and therefore returns 99.
By the way, call echo %^ErrorLevel% just enables us not having to use delayed expansion.
For some reason trying to install a msi executable trough commandline takes too long or never completes. The program is unsigned themes for windows that allows you to run unsupported themes on windows. Its available from here: Download
Im trying to install the 64bit version with:
start /wait "UxStyle Core x64.msi"
The whole batch file looks like this:
#echo off
net stop uxsms
IF "%PROCESSOR_ARCHITECTURE%" == "AMD64" call :install64
IF "%PROCESSOR_ARCHITECTURE%" == "x86" call :install32
IF ERRORLEVEL 1 goto :UxStyleErr
takeown /f "%WINDIR%\Resources\Themes\Aero\aero.msstyles"
icacls "%WINDIR%\Resources\Themes\Aero\aero.msstyles" /grant %USERNAME%:F"
ren "%WINDIR%\Resources\Themes\Aero\aero.msstyles" aero.msstyles.original
copy /y aero.msstyles "%WINDIR%\Resources\Themes\Aero\"
net start uxsms
echo Installation completed. Press any key to reboot or close this dialog if you want to restart later.
pause
shutdown /r /t 0
goto :eof
:install64
start /wait "UxStyle Core x64.msi"
goto :eof
:install32
start /wait "UxStyle Core x86.msi"
goto :eof
:UxStyleErr
echo An error occured while installing UxStyle Core. Installation will now quit.
pause
goto :eof
What am i doing wrong?
Instead of using start /wait to launch the .msi file, I'd recommend calling msiexec.exe directly. You'll also be able to generate a log file which will help you diagnose what is going wrong. So I'd modify your start /wait commands to look like:
msiexec /i "UxStyle Core x64.msi" /l*v x64_installlog.txt
You can add /passive or /quiet to the command to show just a progress bar or run with absolutely no UI respectively.
Please read:
Msiexec (command-line options)
It looks like you are lacking the /QB or /QB switches to run without interaction. Also consider adding REBOOT=R to prevent them MSI from executing any unexpected reboots.
I intend to use the code below to shutdown or restart a computer. Every time I run this, it goes back to set /p var=Type computer name here: Can you please tell me, what is wrong with my script and how to fix it?
#ECHO off
set /p var=Type computer name here:
cls
TITLE %var% power control!!!!
ECHO Copyright © Joshua Reynolds 2012
ECHO USE THIS PROGRAM AT YOUR OWN RISK
pause
:start
cls
ECHO Choose an option below:
ECHO 1. Shutdown
ECHO 2. Restart
ECHO 3. Abort previous choice
ECHO 4. Exit
set /p choice=Type the options number:
if not '%choice%'=='' set choice=%choice:~0,1%
if '%choice%'=='1' goto shutdown
if '%choice%'=='2' goto restart
if '%choice%'=='3' goto abort
if '%choice%'=='4' exit
cls
ECHO "%choice%" is not a valid option please try again
ECHO.
pause
goto start
:shutdown
COLOR 4f
cls
ECHO To shutdown %var%
pause
shutdown /s /m \\%var%
ECHO %var% should now shutdown.
goto start
:restart
COLOR A0
cls
ECHO To restart %var%
pause
shutdown /r /m \\%var%
ECHO %var% should now restart.
goto end
:abort
COLOR 5f
cls
shutdown /a /m \\%var%
goto end
:end
pause
COLOR 0f
goto start
Perhaps the name of your batch script is shutdown.bat and it is in your current directory. So when your script tries to run the SHUTDOWN command, it re-runs your batch script instead.
Either change the name of your script, or else explicitly use shutdown.exe within your script whenever you want to invoke the command.
I'm trying to do a batch program that needs to check if the service is installed before checking if it is running/stopped.
I would just like to ask if there is any way that I can check the ERRORLEVEL of an uninstalled service when the OS is Windows XP.
In my code snippet:
ver | find /I "XP"
if %errorlevel%==0 goto ver_xp
goto ver_nonXP
:ver_xp
echo Windows XP
sc query myService > nul
echo %errorlevel%
if errorlevel ___I goto ServiceOk
if errorlevel ___ goto ServiceError
goto ServiceError
:ver_nonXP
echo Windows is not XP
sc query myService > nul
echo error1_percent %errorlevel%
if %errorlevel%==0 goto ServiceOk
if %errorlevel% NEQ '0' goto ServiceError
goto end
:ServiceError
echo Service is not installed
net helpmsg %errorlevel%
goto end
:ServiceError
rem do some operations here....
I tried to use
if errorlevel 1060 goto ServiceError
It seems that if the service is not installed, the condition above will always be false.
I made the errorlevel ____ because I don't know that the correct condition should be.
sc query myService |find "myService" >nul will do the trick
According to this answer this is possible in batch using method you described How does one find out if a Windows service is installed using (preferably) only batch?
Alternatively you could query with powershell:
$serv_status = get-service "myService"
if($serv_status -ne $null)
{
// do some operations here
}
How do I force the vbs script to run in the cscript host as opposed to the WScript host?
How do I go about reliably determining if vbs is running from the Command Prompt in XP/Vista/7?
Also, if its not running from the command prompt, how would I get the script to launch itself into command prompt?
I'm looking for a short snippet.
There is no property or anything like that you can set, so you are left with ugly hacks like this:
Function ForceCScript()
On Error Resume Next
WScript.StdErr.Write(Chr(7))
If Err.Number <> 0 Then
Err.Clear
On Error GoTo 0
set WshSh=WScript.CreateObject("WScript.Shell")
sh=WshSh.ExpandEnvironmentStrings("%COMSPEC%")
If InStr(sh,"%") = 1 Then sh="cmd.exe"
WshSh.Run(sh&" /K cscript /nologo """&WScript.ScriptFullName&"""")
WScript.Quit()
End If
End Function
call ForceCScript()