How to export .ASCII file in NetLogo 6.2? - netlogo

Question

I would like to know how I can transform a .csv file into raster (ASCII) within NetLogo 6.2?
Well, I can export in .csv to do the conversion later in .ASCII in another program such as R. However, I think it should be possible to export the output in .ASCII by NetLogo itself. At the same time, I would like to know if in terms of processing it would be better to export the output in .csv by NetLogo or in .ASCII? obs.: my world on NetLogo is relatively big
Thanks in advance
extensions [ gis ]
globals [ file output-filename ]
to setup
clear-all
reset-ticks
set output-filename "output-data.csv"
set-default-shape turtles "person"
create-turtles 10 [
setxy random-pxcor random-pycor
]
initialize-data-file
end
to initialize-data-file
file-close-all
if file-exists? output-filename [
file-delete output-filename
]
file-open output-filename
file-print ( word "xcor, ycor" )
end
to go
ask turtles [
wander-about
if ticks mod 50 = 0 [
write-output-data who xcor ycor
]
]
tick
end
to write-output-data [ #turtle-id #xpos #ypos ]
file-open output-filename
file-print ( word #xpos ", " #ypos )
file-flush
; set file gis:patch-dataset xcor ycor
; gis:store-dataset file "test.asc"
end
to wander-about
rt random 40
lt random 40
if not can-move? 1 [ rt 180 ]
fd 1
end

Answer 1

You're on the right track using the GIS extension to export directly to ASCII. Whether you actually need to do this depends entirely on your application- as you say, it may be possible to do what you need simply by exporting a list of turtle coordinates, or of patch values, etc., depending on your needs. Whether you should use ASCII or csv is going to depend on your application, but: for all of my larger models where I actually need to export the whole world for analysis (and, more importantly, to go the other way and import my spatial data into NetLogo), I always use the GIS extension because it seems to be much faster. If I were only exporting turtle characteristics I would probably export to csv.
To answer your specific question here about how to export directly to ASC- here is one way. You need to set up some spatial information for the GIS extension to work with your data, but once you've done that you can create a raster dataset from patch values and export that to a .ASC file that will consist of the .ASC header in addition to a value for each patch in your world. With this example:
extensions [ gis ]
patches-own [ turtle-here ]
to setup
ca
resize-world 0 14 0 14
; Pull in some coordinate system
gis:load-coordinate-system "utm_11.prj"
; Set some envelope. Unless you are actually spatially
; referencing your model, this is just a placeholder.
; If you are using actual spatial coordinates, set these
; appropriately or use gis:envelope-of
gis:set-world-envelope [ 55000 50000 55000 50000 ]
crt 10
reset-ticks
end
to go
ask turtles [
rt random 80 - 40
ifelse not can-move? 1
[ rt 180 ]
[ fd 1 ]
]
if ticks = 50 [
export-ascii
stop
]
tick
end
to export-ascii
ask patches with [ any? turtles-here ] [
set turtle-here 1
]
let ras_out gis:patch-dataset turtle-here
gis:store-dataset ras_out "any_turtle_here.asc"
end
This exports an ascii file that stores the patches-own variable called turtle-here that simply indicates if a turtle is present on the patch at the time of export:
NCOLS 15
NROWS 15
XLLCORNER 50000
YLLCORNER 50000
CELLSIZE 333.333333
NODATA_VALUE NaN
0 0 0 0 0 0 0 0 0 0 0 0 1 0 0
0 0 0 0 0 0 0 1 0 0 0 0 0 0 1
0 0 0 0 0 0 1 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 1 1 1 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 1 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 1 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
0 1 0 0 0 0 0 0 0 0 0 0 0 0 0