kdb: can I use the set keyword to achieve #[`.;`upd;:;.some.function]? - kdb

Question

Say there's an existing function definition .my.func:{[tbl;data] ...} and I want to set the upd function to this lambda.
Are the two lines below equivalent?
#[`.;`upd;:;.my.func]; / #1
`upd set .my.func; / #2
Asking because I see a lot of #1 in the codebase I work with, but #2 seems more succinct, so was wondering if they're somehow different.
I checked https://code.kx.com/q/ref/amend/
"Amend at" #[d; i; v; vy]
This seems to simply define the function upd in the global namespace.
d = `.
i = `upd
v = :
vy = .my.func
After running #1/#2 myself, get`. also seems to suggest #1/2 are equivalent.

Answer 1

The lines are not equivalent in the scenario where \d is used to change namespace. In the examples above set creates the variable in the current namespace and this happens to be the global namespace. # creates the variable in the global namespace.
Example for set using .test namespace creates .test.upd instead.
d).my.func:{x}
q)\d .test
q.test)`upd set .my.func;
q.test)upd
{x}
q.test)\d .
q)upd / upd does not exist in global namespace
'upd
[0] upd
^
q).test.upd / upd exists in .test namespace
{x}
Example for # using upd2 to highlight differences to upd example above. upd2 is created in the global namespace.
q)\d .test
q.test)#[`.;`upd2;:;.my.func];
q.test)upd2 / upd2 does not exist in .test namespace
'upd2
[0] upd2
^
q.test)\d .
q)upd2 / upd2 exists in global namespace
{x}

Answer 2

Following on from Thomas' answer, it's also helpful to know that you can use # to create your function in the current namespace also. The d system command, without an argument, will return the current namespace, and you can use this as the first parameter to #.
q).my.func:{x}
q)\d .test
q.test)\d
`.test
q.test)system"d"
`.test
q.test)#[system"d";`upd;:;.my.func]
`.test
q.test)upd
{x}
Note that this method will only work once the namespace has been initialized first, i.e. something else must exist in the namespace, otherwise you'll see a 'type error.
q)key`
`q`Q`h`o`test
q)\d .new
q.new)#[system"d";`upd;:;.my.func]
'type
q.new)type each(.new;.test)
0 99h

Answer 3

Asking because I see a lot of #1 in the codebase I work with, but #2 seems more succinct, so was wondering if they're somehow different.
You can still use set to assign a value to a variable in the global namespace regardless of a namespace you're currently in, you just need to be a bit more explicit:
q)`upd set .my.func / sets upd in the current namespace
q)`..upd set .my.func / sets upd in the global namespace
q)\d .test
q.test)`upd set {x+1}
`upd
q.test)`..upd set {x+42}
`..upd
q.test)upd
{x+1}
q.test)\d .
q)upd
{x+42}