Restore pack value from hex string - perl

Question

If I have a hex value produced with e.g.
my $hex = sprintf "%v02X", $packed_output
and the $packed_output is the result of pack over a series of numbers i.e.
my $packed_output = pack "L>*", map { $_->[0] << 16 | $_->[1] } #array;
is there a way from that $ hex string to get back the $packed_output?

Answer 1

One approach: Split the string up on period, and convert all the hex-string bytes back to numbers with hex, and then pack them all back together again:
#!/usr/bin/env perl
use strict;
use warnings;
use Data::Dumper;
my $packed_output = pack "L>*", 1, 2, 3, 4, 5, 6;
my $hex = sprintf "%v02X", $packed_output;
# $hex is
# 00.00.00.01.00.00.00.02.00.00.00.03.00.00.00.04.00.00.00.05.00.00.00.06
my $binary = pack "(h2)*", map(hex, split(/\./, $hex));
$Data::Dumper::Useqq = 1;
print Dumper($packed_output, $binary);
# Outputs
# $VAR1 = "\0\0\0\1\0\0\0\2\0\0\0\3\0\0\0\4\0\0\0\5\0\0\0\6";
# $VAR2 = "\0\0\0\1\0\0\0\2\0\0\0\3\0\0\0\4\0\0\0\5\0\0\0\6";
It sounds like what you're really after is an easy way to have a round-trip conversion between binary and textual data, though. Using sprintf to make a hex vector string like the above is not it.
Perl comes with support for industry-standard Base64 encoding, and the older uuencode (Which is built in via pack and unpack, instead of a core module). Examples:
#!/usr/bin/env perl
use strict;
use warnings;
use MIME::Base64;
use feature qw/say/;
my $packed_output = pack "L>*", 1, 2, 3, 4, 5, 6;
# Base64
my $base64 = encode_base64($packed_output, "");
print $base64; # AAAAAQAAAAIAAAADAAAABAAAAAUAAAAG
my $decoded_b64 = decode_base64($base64);
say "It's a match!" if $packed_output eq $decoded_b64;
# uuencode
my $uuencoded = pack "u", $packed_output;
print $uuencoded; # 8`````0````(````#````!`````4````&
my ($decoded_uu) = unpack "u", $uuencoded;
say "Another match!" if $packed_output eq $decoded_uu;