Using logical comparisons to group date ranges - date

Question

I have a dataset with dates and I need to group all of the data into 4 groups. Below is the code I have tried to run.
I get the following error:
ERROR 22-322: Syntax error, expecting one of the following: !, !!, &, (, *, **, +, -, /, <, <=, <>, =, >, ><, >=, AND, EQ, GE, GT,
LE, LT, MAX, MIN, NE, NG, NL, OR, [, ^=, {, |, ||, ~=.
Data _null_;
call symput ('timenow',put (time(),time.));
call symput ('datenow',put (date(), date9.));
run;
data Unemployment_Groups;
set WORK.import;
if missing(observation_date) then unemployment_Grp = .;
else if observation_date le 1969-12-31 THEN Unemployment_Grp = 1;
else if observation_date ge 1970-01-01 AND le 1984-12-31 THEN Unemployment_Grp = 2;
else if observation_date ge 1985-01-01 AND le 2007-12-31 THEN Unemployment_Grp = 3;
else if observation_date ge 2008-01-01 THEN Unemployment_Grp = 4;
run;
title "The current time is &timenow and the date is &datenow";
proc print data=Unemployment_Groups (obs=10) noobs;
run;

Answer 1

Your date value isn't being recognised as such, general syntax for date literals is 'DD Mon YYYY'd (e.g. 27 November 2022 would be '27NOV2022'd).
Also you are not using the logical operators correctly.
Try this:
data unemployment_groups;
set import;
if missing(observation_date) then unemployment_Grp = .;
else if observation_date le '31DEC1969'd then Unemployment_Grp = 1;
else if '01JAN1970'd <= observation_date <='31DEC1984'd then Unemployment_Grp = 2;
else if '01JAN1985'd <= observation_date <='31DEC2007'd then Unemployment_Grp = 3;
else if observation_date ge '01JAN2008'd then Unemployment_Grp = 4;
run;