Saving local Enterprise Architect project settings to database server - enterprise-architect

Question

Is it possible to save the local Sparx Enterprise Architect project preferences (Start > Preferences) to the database server?
We share the project through a database and have changed some settings for the project which seem to not be saved to the database and I suspect they are only saved in the local Windows registry.

Answer 1

There are two types of preferences in EA:
User preferences
Accessed through Start | Appearance | Preferences
Most of these settings are stored in the registry: Computer\HKEY_CURRENT_USER\Software\Sparx Systems\EA400\EA\OPTIONS
Model preferences
Accessed through Settings | Model | Options
These settings are stored in the repository itself.
EA does not support setting users settings on a model level out of the box.
Solution using EA-Matic
EA-Matic is a free open source add-in written by myself.
It supports executing scripts as a reaction to events such as EA_FileOpen()
This script below is used in order to ensure every user of the repository has these same settings.
It basically checks a number of registry values, and updates them if needed. Because EA only reads the registry when starting up, the script closes EA when it has updated a setting, asking the user to restart it.
'[path=\Projects\EA-Matic Scripts]
'[group=EA-Matic]
option explicit
!INC Local Scripts.EAConstants-VBScript
'
' Script Name: Fix Mandatory User Settings
' Author: Geert Bellekens
' Purpose: Check the mandatory user settings in the registry and set them correctly if needed
' Date: 2019-11-05
'
'EA-Matic
const REG_SZ = "REG_SZ"
const REG_DWORD = "REG_DWORD"
const REG_BINARY = "REG_BINARY"
function fixSettings
dim regPath
Dim regkey
dim regValue
dim existingValue
'place in the registry that contains all of the user settings
regPath = "HKEY_CURRENT_USER\Software\Sparx Systems\EA400\EA\OPTIONS\"
'get the EA version
dim eaVersion
eaVersion = Repository.LibraryVersion
dim settingsValid
settingsValid = true
'Fontname13 is only relevant for V15
if eaVersion > 1300 then
settingsValid = settingsValid AND validateRegValue(regPath, "FONTNAME13","Arial", REG_SZ)
else
settingsValid = settingsValid AND validateRegValue(regPath, "FONTNAME","Arial", REG_SZ)
end if
settingsValid = settingsValid AND validateRegValue(regPath, "SAVE_CLIP_FRAME","1", REG_DWORD)
settingsValid = settingsValid AND validateRegValue(regPath, "PRINT_IMAGE_FRAME","1", REG_DWORD)
settingsValid = settingsValid AND validateRegValue(regPath, "SAVE_IMAGE_FRAME","1", REG_DWORD)
settingsValid = settingsValid AND validateRegValue(regPath, "SORT_FEATURES","0", REG_DWORD)
settingsValid = settingsValid AND validateRegValue(regPath, "ALLOW_DUPLICATE_TAGS","1", REG_DWORD)
if not settingsValid then
msgbox "Mandatory user settings have been corrected." & vbNewLine & "Please restart EA",vbOKOnly+vbExclamation,"Corrected mandatory user settings!"
Repository.Exit
end if
end function
function validateRegValue(regPath, regKey, regValue, regType)
Dim shell
' Create the Shell object
Set shell = CreateObject("WScript.Shell")
dim existingValue
on error resume next
'read registry value
existingValue = shell.RegRead(regPath & regkey)
'if the key doesn't exist then RegRead throws an error
If Err.Number <> 0 Then
existingValue = ""
Err.Clear
end if
on error goto 0
'check the value in the registry with the desired value
if Cstr(existingValue) <> regValue then
'write the correct value to the registry
shell.RegWrite regPath & regkey, regValue, regType
'return false
validateRegValue = false
else
'value was already OK, return true
validateRegValue = true
end if
end function
function EA_FileOpen()
fixSettings
end function

Answer 2

In addition to Geerts excellent answer I would like to add that you can alter the registry location for the options (which go to registry and not to the database) by supplying an option to the command line when you open EA.
E.g. if you invoke EA with
"C:\Program Files (x86)\Sparx Systems\EA\EA.exe" /regkey:P1
it will create/access the key HKEY_CURRENT_USER\Software\Sparx Systems\P1 rather than \EA400 which is the default.
The options itself are found under the OPTIONS key below.
This gives you the opportunity to handle different settings out of the box. At least for those options Sparx decided to go to the registry rather than the database. (Editor's note: It will be an options jungle in any case)