Catching punctuation in AppleScript for use in a Mail Rule - sed

Question

I get a ton of spam mail where the from or reply to has punctuation in the address. Instead of creating a giant rule with a bunch of rows with Contains "!" and such, I want to use a script in a mail rule to send everything from an address with punctuation other than a dot and an at to the trash.
What can I replace = "hello world" in the example below to catch punctuation?
tell application "Mail"
set theSelection to selection
set theMessage to item 1 of theSelection
subject of theMessage
if subject of theMessage = "hello world" then
set mailbox of theMessage to mailbox "Trash"
end if
end tell
I've looked at some get shell script and sed examples but didn't understand how to specify that I only want to find punctuation.

Answer 1

What you’re looking for is a regular expression; AppleScript doesn’t have them by default. There are a couple of ways around this.
The easiest AppleScript way is to have a whitelist of valid characters, and then check your string to see if it contains anything not in that whitelist.
Because we don’t want to be trashing messages willy-nilly while testing, I’ve replaced the trash line with a display dialog line. Because the AppleScript calls a function, I also do this outside of the tell block. While you can call local functions inside a tell block, it’s easier in a short script like this to not worry about it.
property goodCharacters : "abcdefghijklmnopqrstuvwxyz.#"
tell application "Mail"
set theSelection to selection
set theMessage to item 1 of theSelection
set theSubject to theSubject of theMessage
end tell
if badCharacter(theSubject) is true then
display dialog theSubject & " is bad."
--tell application "Mail" to set the mailbox of theMessage to mailbox "Trash"
end if
--return true of the text contains any non-good character
on badCharacter(theText)
repeat with theCharacter in theText
if goodCharacters does not contain theCharacter then
return true
end if
end repeat
return false
end badCharacter
The badCharacter handler returns true if any of the characters in the given string are not in the list of good characters. Otherwise, it returns false.
You may also find these useful when you switch from testing against the subject to testing against what you said you want, which is the from and the reply-to:
set theSender to extract address from the sender of theMessage
set theReply to extract address from the reply to of theMessage
If you’re familiar with JavaScript, you may find JXA (JavaScript for Automation) more useful, because JavaScript does have regular expressions. In the upper left of Script Editor, change “AppleScript” to “JavaScript”.
mail = Application('Mail');
trash = mail.mailboxes.byName("Trash")
theSelection = mail.selection();
theMessage = theSelection[0];
theSender = theMessage.sender().replace(/^.*<([^>]+)>/, "$1");
theReply = theMessage.replyTo();
theSubject = theMessage.subject();
//text.search returns the index of the match
//it returns -1 on no match
//so if the result is 0 or greater, it found a match
//the caret (^) reverses the sense of the brackets
//where [a-z.#] would match *on* any character from a to z as well as the period and #
//[^a-z.#] matches any any character *other than* a-z, ., and #
if (theSubject.search(/[^a-z.#]/i) >= 0) {
mail.move(theMessage, {to: trash})
}
Other options might include using a third-party tool to add regular expressions to AppleScript. You might also use do shell script to use sed or some other command-line tool to parse the text you need parsed; I’m inclined to think running unknown text to the command line is dangerous, however.
And AppleScript does have tools for strings besides =. As shown above, it has contains (or does not contain), but it also has starts with and ends with. You can even get the words of any string, which will remove all punctuation.