Intersection of arrays of objects based on object property value - coffeescript

Question

array1 = [ { id: "a", score: 1 }, { id: "b", score: 3 }, { id: "c", score: 8 }]
array2 = [ { id: "a", score: 2 }, { id: "z", score: 5 }, { id: "c", score: 1 }]
array3 = [ { id: "a", score: 3 }, { id: "f", score: 2 }, { id: "c", score: 2 }]
How can I get a result array containing only objects that have an id property value that exists and is the same in all arrays ? ie:
resultyArray = [
{ id: "a", score: 1 },
{ id: "a", score: 2 },
{ id: "a", score: 3 },
{ id: "c", score: 8 },
{ id: "c", score: 1 },
{ id: "c", score: 2 }
]

Answer 1

Let's say that the objects whose ids appear on every array are "ubiquitous" (naming things is hard =P):
filterUbiquitousObjects = (arrays...) ->
objectsById = {}
(objectsById[obj.id] or= []).push obj for obj in arr for arr in arrays
[].concat (arr for id, arr of objectsById when arr.length is arrays.length)...
array1 = [{ id: "a", score: 1 }, { id: "b", score: 3 }, { id: "c", score: 8 }]
array2 = [{ id: "a", score: 2 }, { id: "z", score: 5 }, { id: "c", score: 1 }]
array3 = [{ id: "a", score: 3 }, { id: "f", score: 2 }, { id: "c", score: 2 }]
console.log filterUbiquitousObjects array1, array2, array3
# Output:
# [{id:"a", score:1}, {id:"a", score:2}, {id:"a", score:3}, {id:"c", score:8},
# {id:"c", score:1}, {id:"c", score:2}]
The nested for loops are a bit ugly, but this should be O(n) (being n the total number of objects) unless i screwed up somewhere.
Update: you can also do:
res = []
for id, arr of objectsById when arr.length is arrays.length
res = res.concat arr
res
Instead of the cryptic [].concat (arr for id, arr of objectsById when arr.length is arrays.length)... line. It's arguably more readable and will generate saner JS :)