How can I cut out a section of a string using Perl? - perl

Question

I need to cut some characters out of the middle of a string; the starting and ending positions of the character sequence to be cut will vary.
For example, say I have the sentence
The quick brown fox jumped over the lazy dog
I need to count forward from the first character until I get to fox, assign the character position of the f to a variable, continue counting forward until I get to 'the' and then cut out the characters between and including the initial f and the final e.
Note
There is an e in jumped which is between fox and the, this should be ignored, it must find the position of the e in the.

Answer 1

To remove a section of a string where you're not sure of all the intervening characters, you can use the substitution operator. If there's a match, the position of the beginning of the match (zero-indexed) is stored in $-[0] (or $LAST_MATCH_START[0] if you use English;):
use strict;
use warnings;
use 5.010;
my $string = 'The quick brown fox jumped over the lazy dog';
$string =~ s/fox.*the//;
say "Matched at char $-[0]" if defined $-[0];
say "New string: $string";
Output:
Matched at char 16
New string: The quick brown lazy dog
Which "the"?
Note that the regex I used is greedy, so it will gobble up every the until the last. For the string:
The quick brown fox jumped over the lazy dog and the sleepy cat
you will get:
Matched at char 16
New string: The quick brown sleepy cat
To stop at the first occurrence of the, change the substitution to:
s/fox.*?the//;
Whole words only
Both of the regexes above will still match partial words. The string:
The quick brown foxhole jumped over their lazy dog
gives:
Matched at char 16
New string: The quick brown ir lazy dog
To only match whole words* change the substitution to:
s/(?:^|\s+)\Kfox\s+.*\s+the(?=\s+|\z)//; # greedy
or
s/(?:^|\s+)\Kfox\s+.*?\s+the(?=\s+|\z)//; # non-greedy
* It's hard to define what counts as a whole word in an English sentence. The above expects a word to be surrounded on both sides by one or more spaces or to be at the beginning or end of the string, which excludes things like in-the-know, but also excludes "fox" and the,. This is obviously not a great definition.

Answer 2

I have the sentence
The quick brown fox jumped over the lazy dog
I need to count forward from the first character until I get to 'fox', asign the character position of 'f' to a variable, continue counting forward until I get to 'the' and then cut out the characters, including and between, 'f' and 'e'.
I am quoting your problem description because it indicates the C mindset with which you are approaching Perl. At a bit higher level than C, your problem is to actually to cut out the words between "brown" and "lazy". Perl allows you to directly express this idea:
$ perl -wE 'say join(" ", (split /\s+(?:fox|the)\s+/, "The quick brown fox jumped over the lazy dog")[0, 2])'
The quick brown lazy dog
Or, using the range operator:
$ perl -wE 'say join " ", grep !(/^fox$/ .. /^the$/), split " ", "The quick brown fox jumped over the lazy dog"'
The quick brown lazy dog
which literally reads "take all the words not between 'fox' and 'the', join them together using a single space as the word separator, and print the resulting sentence."
If the original sentence has many, many words, the first one might be more efficient as it will only ever create a three element list.
You can read more about the range operator in perldoc perlop. Since you are just beginning to learn Perl, you should read everything mentioned in perldoc perltoc at least once, including all the FAQ sections.