Setting the content of an outgoing message fails - email

Question

i tried to create an auto reply script but as soon as i try to set the content of the outgoing message it throws an error and tells me that "content" can't be read.
set replyMessage to reply thisMessage with opening window
delay 2
set rich text content of replyMessage to "Hallo"
any ideas?
edit: full code:
tell application "Mail"
set replyList to {}
set inboxMessages to every message in inbox
# get Einsatz mail from all emails
repeat with thisMessage in inboxMessages
set thisContent to content of thisMessage
set thisSender to sender of thisMessage
if thisSender contains "#pos-lifestyle.de" then
if thisContent contains "nochmal alle wichtigen Informationen zum Heimspiel" then
if thisContent contains "deinen Einsatz per Mail" and thisContent contains "Bitte bestätige" then
set end of replyList to thisMessage
set read status of thisMessage to true
end if
end if
end if
end repeat
# reply to all Einsatz mails
repeat with thisMessage in replyList
set replyMessage to reply thisMessage with opening window
delay 2
set content of replyMessage to (("Hallo," & return & "hiermit bestätige ich den Einsatz." & return & "Mit besten Grüßen" & return & "Max Mustermann") as rich text)
end repeat
end tell

Answer 1

I now complete the full script based on your latest update.
I tested it with several cases, and it is 100% working for me. I just made couple of simplifications.
Also, I have set the targets (sender and content) on top of the script to make it easier to read and test (to test , I just have to change values of 4 lines on top with possible values from my mail box !).
set TargetSend to "#pos-lifestyle.de"
set Target1 to "nochmal alle wichtigen Informationen zum Heimspiel"
set Target2 to "deinen Einsatz per Mail"
set Target3 to "Bitte bestätige"
tell application "Mail"
set replyList to {}
set inboxMessages to every message in inbox whose sender contains TargetSend
repeat with thisMessage in inboxMessages
set thisContent to content of thisMessage
if (thisContent contains Target1) and (thisContent contains Target2) and (thisContent contains Target3) then
set end of replyList to thisMessage
set read status of thisMessage to true
end if
end repeat
# reply to all Einsatz mails
repeat with thisMessage in replyList
set replyMessage to reply thisMessage with opening window
delay 2
set content of replyMessage to (("Hallo," & return & "hiermit bestätige ich den Einsatz." & return & "Mit besten Grüßen" & return & "Max Mustermann") as rich text)
end repeat
end tell

Answer 2

I figured out a way to prevent this error from happening
set TargetSend to "#pos-lifestyle.de"
set Target1 to "nochmal alle wichtigen Informationen zum Heimspiel"
set Target2 to "deinen Einsatz per Mail"
set Target3 to "Bitte bestätige"
set MyName to "Max Musterman"
tell application "Mail"
set replyList to {}
set inboxMessages to every message in inbox whose sender contains TargetSend
# look for Einsatz mails
repeat with thisMessage in inboxMessages
set thisContent to content of thisMessage
if (thisContent contains Target1) and (thisContent contains Target2) and (thisContent contains Target3) then
set end of replyList to thisMessage
set read status of thisMessage to true
end if
end repeat
# reply to all Einsatz mails
repeat with thisMessage in replyList
set replyMessage to reply thisMessage with opening window
repeat until exists (window 1 whose name = "Re: " & subject of thisMessage)
end repeat
delay 0.1
tell application "System Events"
tell process "Mail"
set frontmost to true
keystroke "Hallo"
keystroke return
keystroke "Hiermit bestätige ich den Einsatz."
keystroke return
keystroke "Mit besten Grüßen"
keystroke return
keystroke MyName
keystroke return
end tell
end tell
#send replyMessage
end repeat
end tell