APEX 4.2 validation, at least one row must have a value - oracle-sqldeveloper

Question

I have a table that defines users with administrative rights. The table has a column labeled ADMINISTRATOR. The apex tabular form is set so the column is displayed as check boxes. when a check is present, the value is 1. When the check is empty, the value is null.
The problem I have is any admin accessing this page can add or revoke admin privileges to anyone. This means if an admin accidentally or intentionally revokes permissions from all the other admins including himself, no one can access that tool on the front end.
I want to establish a validation that requires the system to have at least one administrator and throw an error if someone tried to update the table with no 1 in the ADMINISTRATOR column.
I have been trying to determine what validation would work best.
My most recent attempts have been:
Type: Function returning a boolean
Expression:
declare
admincount number(8);
begin
select count(administrator) into admincount from supervisor;
if admincount < 1 then
return false;
else
return true;
end if;
end;
When I try to run this script on Oracle SQL Developer, I get:
Error report -
ORA-06550: line 8, column 4:
PLS-00372: In a procedure, RETURN statement cannot contain an expression
ORA-06550: line 8, column 4:
PL/SQL: Statement ignored
ORA-06550: line 10, column 4:
PLS-00372: In a procedure, RETURN statement cannot contain an expression
ORA-06550: line 10, column 4:
PL/SQL: Statement ignored
06550. 00000 - "line %s, column %s:\n%s"
*Cause: Usually a PL/SQL compilation error.
*Action:
What is wrong with this code? Am I applying this expression to the wrong location?

Answer 1

What happens in apex is that your block is actually converted into a function.
declare
admincount number(8);
begin
select count(administrator) into admincount from supervisor;
if admincount < 1 then
return false;
else
return true;
end if;
end;
Is internally changed to be this function with a return value. Then the engine calls this. An anonymous block in isolation can not have a return statement or you will get the error you are seeing.
declare
ret boolean;
function x return boolean is
begin
declare
admincount number(8);
begin
select count(administrator) into admincount from supervisor;
if admincount < 1 then
return false;
else
return true;
end if;
end;
end;
begin
ret := x;
end;
What would be best is to move your logic into an actual function
create or replace function is_admin return boolean
as
admincount number(8);
begin
select count(administrator) into admincount from supervisor;
if admincount < 1 then
return false;
else
return true;
end if;
end;
Then you can test this function in sqldev / sqlcl or any tool.
The resulting expression then used in APEX would simply be
return is_admin;

Answer 2

That won't work in SQL Developer; you must return BOOLEAN into something (another PL/SQL procedure) and then decide what to do. Here's an example:
SQL> select * From ts65_supervisor order by id;
ID ADMINISTRATOR
---------- -------------
1 1
2 1
3
4
5 1
SQL> create or replace function f_super return boolean as
2 admincount number;
3 begin
4 select count(administrator) into admincount from ts65_supervisor;
5
6 return admincount > 1;
7 end;
8 /
Function created.
Is it OK? (3 admins - should be):
SQL> begin
2 if f_super then
3 dbms_output.put_line('OK, more than 1 admin');
4 else
5 dbms_output.put_line('The last one');
6 end if;
7 end;
8 /
OK, more than 1 admin
PL/SQL procedure successfully completed.
After update?
SQL> update ts65_supervisor set administrator = null where id < 5;
4 rows updated.
SQL> begin
2 if f_super then
3 dbms_output.put_line('OK, more than 1 admin');
4 else
5 dbms_output.put_line('The last one');
6 end if;
7 end;
8 /
The last one
PL/SQL procedure successfully completed.
SQL>
I'd suggest you NOT to test it in SQL Developer, but directly in Apex - it'll wrap your code into its own BEGIN - END block(s) and that function might work just fine (note the difference between your code and mine - you don't actually need IF-THEN-ELSE - a simple RETURN with a condition is enough for Oracle to know which one of TRUE/FALSE to return).