Agent garbage collection in NetLogo - netlogo

Question

I'm using TSP to illustrate Genetic Algorithms in a class. The students are supposed to write the GA. There is a forever button that will run the GA continually. Whenever a new best path is found it is saved and displayed.
To show how this is supposed to work, I wrote a greedy-path procedure. Starting at a random node, it builds a path by taking the shortest link that attaches to an unused node.
Here is the (slightly simplified) forever button procedure that calls greedy-path.
to continual-greedy-path
let new-path greedy-path ;; Creates a new path agent
if [path-length] of new-path < [path-length] of best-path [
set-new-best-path new-path
display-best-path
]
end
Each call to greedy-path creates a new path agent to store the path. The problem is that I am running out of memory. With the continual-greedy-path button on, count paths keeps increasing and memory is chewed up rapidly, even though very few better paths are ever found. (There is only one greedy path from any starting point. So the maximum number of new paths is the number of nodes. The problem occurs even when there are only two nodes and no better paths are ever found!)
Are the unused path agents not garbage collected at the end of continual-greedy-path? Is there something else I'm missing?
The only new agents that are being generated are paths. There are no new nodes or edges.
Thanks.
Update: A bit of experimentation suggests that there is garbage collection. Perhaps it just can't keep up with the rate of new path generation. But why doesn't the system slow down rather than run out of memory?

Answer 1

It looks like the turtles created by continual-greedy-path are not removed, just the variable new-path. So, your paths are still present and their count increasing, as the new-turtles here:
globals [ max-x ]
to setup
ca
set max-x min-pxcor
reset-ticks
end
to new-max-x
let new-t new-turtle
if [xcor] of new-t > max-x [
set max-x [xcor] of new-t
]
end
to-report new-turtle
let x nobody
crt 1 [
set x self
set xcor random-pxcor
]
report x
end
I think the quick fix would be to manually remove those path agents that do not meet your criteria with something like:
globals [ max-x max-x-turt]
to setup
ca
set max-x min-pxcor
set max-x-turt nobody
reset-ticks
end
to new-max-x
let new-t new-turtle
ifelse [xcor] of new-t > max-x [
set max-x [xcor] of new-t
if max-x-turt != nobody [
ask max-x-turt [
die
]
]
set max-x-turt new-t
] [
ask new-t [
die
]
]
end
to-report new-turtle
let x nobody
crt 1 [
set x self
set xcor random-pxcor
]
report x
end