sed to match and replace 2 consecutive lines? - sed

Question

I want to match 2 consecutive lines then replace it. For example this pattern:
[0-9]\(.*\)\n[0-9]\(.*\)
so basically both lines are started with a number.
Then replace it:
\2\n\1
Means swap the line content and ditch the leading number.
example file 1:
adfa
adaf
dfd
1 1a
2 2b
3 3d
adfa
sdfa
4 4a
5 5b
6 6d
7 7k
example file 2:
adfa
adaf
dfd
aaa
1 1a
2 2b
3 3d
sdfa
4 4a
5 5b
6 6d
7 7k
Many answers online suggest using N; or 1!N; but This will not work.
The reason is N; will start from 1st line, then read every 2 lines, 1!N; will start from 2nd line, then read every 2 lines. But what I want is to read each line and its next line to match. If N and N+1 lines matched we replace on this 2 lines, then move to the N+3 and N+4 line to match, If no match, we move to N+4 and N+5 ...
The expected result will be following for both example files:
2b
1a
5b
4a
7k
6d
The failed commands:
sed 'N;s%[0-9]\(.*\)\n[0-9]\(.*\)%\2\n\1%;t;d' test0.txt
3d
2b
5b
4a
7k
6d
sed 'N;s%[0-9]\(.*\)\n[0-9]\(.*\)%\2\n\1%;t;d' test1.txt
2b
1a
5b
4a
7k
6d
sed '1!N;s%[0-9]\(.*\)\n[0-9]\(.*\)%\2\n\1%;t;d' test0.txt
2b
1a
6d
5b
7 7k
sed '1!N;s%[0-9]\(.*\)\n[0-9]\(.*\)%\2\n\1%;t;d' test.txt
3d
2b
6d
5b
7 7k

Answer 1

If you use D instead of d, i.e. delete first line of pattern-space and repeat-if-not-empty, then it works, e.g.:
sed -nE 'N; s/^[0-9] (.*)\n[0-9] (.*)/\2\n\1/; ta; D; :a; p' infile
Or even cleaner as suggested by #potong:
sed 'N;/^[0-9] \(.*\)\n[0-9] \(.*\)/!D;s//\2\n\1/' infile
Output:
2b
1a
5b
4a
7k
6d

Answer 2

A imperfect way to achieve it
sed -nr '/^[0-9]/{N;s/.*([0-9][[:alpha:]]).*([0-9][[:alpha:]])/\2\n\1/p}'
We use N only if the line start by a number.
Then we could use regular expression to do as we need.
This regexp is designed by your example file, and should be adjusted if the format of your file changed.