Substitute text only between tokens (single-line) - sed

Question

I'd like to remove spaces in strings that are between square brackets, with a single-line input.
More precisely, strings that match \[[a-zA-Z0-9 ,]+\] (caseless alphanum comma and space, between square brackets)
For example:
[ "This is a test": [a, b, c] ]
Should become:
[ "This is a test": [a,b,c] ]
I have tried several attempts with branching but couldn't find a syntax that worked.
For example:
/\[[a-zA-Z ,]\+\]/ba; :a;s/ //g;
but this replaces spaces on the whole line, as sed is line-based (my input is single-line).
I also tried the ;e command which would work if the whole string was prefixed with echo " and suffixed with ", but then that would be a single/double-quote escape hell (the whole string may contain ' and ").
GNU sed is welcome, but I would like to keep the dependencies minimal, so no perl unless required and no ruby, python, php...
Indeed, I know the following works perfectly, but php is a too large dependency:
echo preg_replace_callback(
"/\[[a-zA-Z ,]+\]/",
function ($m) { return str_replace(" ", "", $m[0]); },
'{"a":{"a":{"a":"a b c"},"b":{"b":[a, b]}}}'
);
outputs:
{"a":{"a":{"a":"a b c"},"b":{"b":[a,b]}}}

Answer 1

First pass — it works, but it is clumsy
Here is a solution that works with GNU and BSD sed:
sed -E \
-e '/\[[[:alnum:] ,]+\]/ {
s/\[([[:alnum:] ,]+)\]/^B\1^E/
:a
s/(^B[[:alnum:],]*) +/\1/
t a
s/^B/[/
s/^E/]/
}' \
data
The appearances of ^B and ^E are control characters (Control-B and Control-E in the original) that aren't going to appear in the actual text. (When first copied, I got ^B showing as and ^E showing as .)
Explanation:
/\[[[:alnum:] ,]+\]/ { — match lines containing square brackets with alphanumerics plus space and comma between them, and do the action sequence from { to the matching }.
s/\[([[:alnum:] ,]+)\]/^B\1^E/ — replace the square brackets with the control characters.
:a — set a label
s/(^B[[:alnum:],]*) +/\1/ — replace a ^B plus a sequence of alphanumerics or commas (which is captured) and a string of one or more spaces with just the capture.
t a — if the s/// command made a change, jump back to label a.
s/^B/[/ — replace the ^B with open square bracket.
s/^E/]/ — replace the ^E with close square bracket.
} — done
The branch is necessary because normally, the s/// operator won't rescan material that it has just substituted, whereas it is crucial that this keeps rescanning.
Given the slightly more extensive input file:
\[[a-zA-Z0-9 ,]+\] (caseless alphanum comma and space, between square brackets)
For example:
[ "This is a test": [a, b c] ]
[ "This is a test": [a, b, c] ]
[ "This is test 3": [ XXX, YYY, XXX ] ]
Should become:
[ "This is a test": [a,bc] ]
[ "This is a test": [a,b,c] ]
[ "This is test 3": [XXX,YYY,XXX] ]
the script generates:
\[[a-zA-Z0-9 ,]+\] (caseless alphanum comma and space, between square brackets)
For example:
[ "This is a test": [a,bc] ]
[ "This is a test": [a,b,c] ]
[ "This is test 3": [XXX,YYY,XXX] ]
Should become:
[ "This is a test": [a,bc] ]
[ "This is a test": [a,b,c] ]
[ "This is test 3": [XXX,YYY,XXX] ]
Second pass — it pays to review and refine
Looking at it, the ^E is not necessary, and maybe not the ^B either. The version above only deals with the first such set of square brackets on the line. You need more sensitive detector regexes (ones that insist on at least one space in between the markers) to handle multiple such patterns on a single line.
For example:
sed -E \
-e ':a
/\[[[:alnum:],]* [[:alnum:] ,]*\]/ s/(\[[[:alnum:],]*) +/\1/
t a' \
data
Explanation:
:a – set a label
/\[[[:alnum:],]* [[:alnum:] ,]*\]/ — if the line contains an open square bracket, zero or more alphanumeric-or-comma characters, one or more blanks, and zero or more alphanumeric-or-comma-or-blank followed by close square bracket, then …
s/(\[[[:alnum:],]*) +/\1/ — replace the open square and sequence of zero or more alphanumeric-or-comma characters and one or more blanks by just the non-blanks, and …
t a — jump to label a if there was a substitution done
Given:
[ "This is a test": [a, b c] ]
[ "This is test 2": [a, b, c] ]
[ "This is test 3": [ XXX , YYY , XXX ] ]
[ "This is test 4": [ XXX , YYY , XXX ] [ 1 , 2 , 3 ] ]
[ "This is test 5": [ XXX , YYY , XXX ] [ 1 , 2 , 3 ] [ abc ] [ ] ]
this produces:
["This is a test": [a,bc] ]
["This is test 2": [a,b,c] ]
["This is test 3": [XXX,YYY,XXX] ]
["This is test 4": [XXX,YYY,XXX] [1,2,3] ]
["This is test 5": [XXX,YYY,XXX] [1,2,3] [abc] [] ]
This is mostly equivalent to the answer by Beta; it could be further simplified by eliminating the match before the substitute command and modifying (slightly complicating) the substitute so it matches the work by Beta.

Answer 2

I think this will work:
sed -e ':a' -e 's#\(\[[a-zA-Z0-9,]*\) \([a-zA-Z0-9 ,]*\]\)#\1\2#
t a' filename