SAS separete Dates from one variable - date

Question

i need to separate every date that I create in the next sentence so I'm able to create a variable for every date.
The next loop create dates in one variable.
data _null_;
End_date= /*today()-1;*/ '30JUN2021'd;
call symput('days',intck('day',intnx("year",End_date,-1,'b'), End_date));
End_month=intnx("month",End_date,0,'e');
format End_month End_date ddmmyy10.;
run;
data _null_;
length varnew $30000.;
End_date= /*today()-1;*/ '30JUN2021'd;
do i=0 to &days.;
if i=0 then do;
varnew=put(intnx("year",End_date,-1,'b'),ddmmyy10.);
end;
else do;
if intnx("year",End_date,-1,'b')+i ne intnx("month",intnx("year",End_date,-1,'b')+i,0,'e') then do;
varnew= trim(varnew)||" "||put(intnx("year",End_date,-1,'b')+i,ddmmyy10.);
end;
else do;
varnew= trim(varnew)||" "||put(intnx("year",End_date,-1,'b')+i,ddmmyy10.)||" "||put(intnx("year",End_date,-1,'b')+i,mmyys7.);
end;
end;
end;
if End_date ne intnx("month",end_date,0,'e') then do;
call symput('varnew',trim(varnew)||" "||put(intnx("year",End_date,-1,'b')+&days.,mmyys7.)||" "||put(intnx("year",End_date,-1,'b')+&days.,mmyys7.)||"*");
end;
else do;
call symput('varnew',trim(varnew)||" "||put(intnx("year",End_date,-1,'b')+&days.,mmyys7.)||"*");
end;
run;
%put --&varnew.--;
That looks like
--01/01/2020 02/01/2020 03/01/2020 04/01/2020 05/01/2020 06/01/2020 07/01/2020 08/01/2020 09/01/2020 10/01/2020 11/01/2020
12/01/2020 13/01/2020 14/01/2020 15/01/2020 16/01/2020 17/01/2020 18/01/2020 19/01/2020 20/01/2020 21/01/2020 22/01/2020 23/01/2020
24/01/2020 25/01/2020 26/01/2020 27/01/2020 28/01/2020 29/01/2020 30/01/2020 31/01/2020 01/2020 01/02/2020 02/02/2020 03/02/2020
04/02/2020 05/02/2020 06/02/2020
So what I want is to create for every date a variable to look like
| VAR1 | VAR2 | VAR3 |
|-------------| ------------|-------------|
| 01/01/2020 | 02/01/2020 | 03/01/2020 |

Answer 1

You can do this all in one step. Set your end date and start date, then loop through and create a macro variable for each one. The first argument of call symputx() accepts functions as well. We'll create a counter for each variable, then append it to the name var.
The output statement and dataset created are not needed and are here for descriptive purposes only.
data dates;
end_date = '30JUN2021'd;
start_date = intnx('year', end_date, -1, 'B');
do date = start_date to end_date;
i = date-start_date+1;
output;
/* Dynamically create new macro variables named var1, var2, etc. */
call symputx(cats('var', i), put(date, ddmmyys10.) );
end;
format end_date start_date date ddmmyys10.;
run;
%put var1: &var1;
%put var2: &var2;
%put var3: &var3;
Output:
var1: 01/01/2020
var2: 02/01/2020
var3: 03/01/2020
If you're trying to create data step variables where you have one variable for each date, you can do a similar thing with arrays. You can't dynamically assign an array size, so we'll set our end/start dates and array size using macro variables.
/* Create date constants for array */
%let end_date = '30JUN2021'd;
%let start_date = %sysfunc(intnx(year, %sysfunc(putn(&end_date, 8.)), -1, B));
%let n_dates = %eval(%sysfunc(putn(&end_date., 8.)) - &start_date.+1);
/* Generate dates for each array variable */
data dates;
end_date = &end_date.;
start_date = &start_date.;
array var[&n_dates.];
do date = start_date to end_date;
i = date-start_date+1;
var[i] = date;
end;
format start_date end_date var: ddmmyys10.;
run;
Output:
var1 var2 var3
01/01/2020 02/01/2020 03/01/2020